Macro De Talar Urgente...

**axel123** · 01-Sep-2014

Hola, Necesito una macro de Talar y que guarde la madera porfavor porque ahy muchas y son re dificiles y la unica que entiendo, no me anda... please ya me canse de buscar y leer.

**Tinerfe el grande** · 01-Sep-2014

Iniciado por axel123

Hola, Necesito una macro de Talar y que guarde la madera porfavor porque ahy muchas y son re dificiles y la unica que entiendo, no me anda... please ya me canse de buscar y leer.

Esta macro la usé y funciona. Puedes usar si no la macro de Nilaween que consta de 3 macros que van mediante Call´s me parece, esta es fácil de configurar y no tienes que hacer railes recuerda cambiar la ID del libro de runas y la ID del cofre, y las coordenadas del click en las partes en rojo de cada runa.

Iniciado por Joseph

Macro de talar terminada,xd

Explicación: La macro usa la hacha mágica. Está configurada para talar en tres bosques diferentes, tala1, tala2 y tala3. Las posiciones de las runas en el libro: En la primera posición del libro la casa, lógicamente al lado tenéis que poner el cofre donde dejareis regs y comida, sólo de una clase, peras o manzanas o ...., en la 2, 3 y 4 los bosques. Las coordenadas %posicionx_ son el #CHARPOSX de donde recaléis, es un sistema de seguridad por lo de los saves o lagazos varios. Por último cambiar el id del libro de runas y el cofre. Pongo en rojo lo que es obligatorio modificar, podéis comenzar la macro en cualquier punto de tala. Cuando te tira la madera la va recogiendo y arrastrando al siguiente punto hasta llegar a cierto peso total, %peso, entonces es cuando recalea, suerte.

Código:

;===========================
; Macro: Talar
; Autor: JoSePh
; EasyUO 1.5, V.202
; Servidor: Ultima Alianza
; Cliente: 7.0.8.2
;===========================
=========CONFIGURAR=========
set %libro_runas WBCPLND
set %cofre XANYTND
set %hacha FSF_ASF
set %casax 129
set %casay 70
set %posicionx_casa 1266
set %tala1x 129
set %tala1y 85
set %posicionx_tala1 667
set %tala2x 129
set %tala2y 100
set %posicionx_tala2 539
set %tala3x 129
set %tala3y 115
set %posicionx_tala3 527
============================
set %comida _PQD_MQE_FUD_OQE_YRD_YWI_AXI_VQE_BDF
+_TQE_KPE_QQD_RQE_SQD_SPE_JQE_ZPE_IQE_YSD_GQE_HND
set %arboles _3277_3278_3280_3281_3283_3284_3286_3287_3288
+_3289_3290_3291_3293_3294_3296_3297_3299_3300_3302_3303
set %regs JUF
set %regs2 MZF
set %regs3 KUF
set %madera ZLK
set %peso 750
set %Lugar 0
set %pasos 6
set %numero_arboles_talados 0
set %arboles_talados _
display Comienza la Macro!!
initevents
inicio:
event sysMessage * Escaneando... *
gosub buscar_arbol
if %lugar > 9
set %lugar 0
wait 5
if %arbol_encontrado = #true
{
event sysmessage * Llendo.. *
gosub mover
event sysmessage * Talando *
gosub talar
event sysmessage * Arboles Talados: %numero_arboles_talados
}
else
gosub caminar
goto inicio
sub buscar_arbol ;<==========================>
set %inicio_x ( #CharPosX - %pasos )
set %inicio_y ( #CharPosY - %pasos )
set %fin_x ( #CharPosX + %pasos  )
set %fin_y ( #CharPosY + %pasos  )
tile init
for %buscar_y %inicio_y %fin_y
{
for %buscar_x %inicio_x %fin_x
{
tile get %buscar_x %buscar_y 1 #CursKind
tile cnt %buscar_x %buscar_y #CursKind
if #TileCnt > 1
{
set %fin_ciclo #TileCnt
for %ciclo 0 %fin_ciclo
{
tile get %buscar_x %buscar_y %ciclo
if _ , #TileType , _ in %arboles
{
set %expresion  _ , %buscar_x , : , %buscar_y , _
wait 5
if %expresion in %arboles_talados
{
set %arbol_encontrado #false
}
else
{
event sysmessage *  Encontrado Arbol. *
set %mover_x %buscar_x
set %mover_y %buscar_y
set %tipo #TileType
set %arbol_encontrado #true
return
}
}
}
}
}
}
event sysmessage * Area Limpia *
return
sub talar ;<==========================>
set #LTargetX %mover_x
set #LTargetY %mover_y
set #LTargetZ 0
set #LTargetKind 3
set #LTargetTile %tipo
set %numero_arboles_talados %numero_arboles_talados + 1
set %arboles_talados %arboles_talados , %mover_x , : , %mover_y , _
finditem %madera C_, #BACKPACKID
exevent drag #FINDID
exevent dropc #BACKPACKID
wait 20
talar:
finditem %hacha
set #LOBJECTID #FINDID
event macro 17
target
event Macro 22
wait 10
Set %tiempo ( #SCnt + 10 )
diario:
wait 1
if %tiempo < #SCnt
goto talar
scanJournal 1
if pones_el in #JOURNAL || no_obtienes_ in  #JOURNAL
goto talar
if aqui_no_ in #JOURNAL || Parece_que_ in #JOURNAL || No_lo_ in #JOURNAL || Prueba_a_ in #JOURNAL || _ni_idea_ in #JOURNAL || _muy_lejos_ in #JOURNAL || no_puedes_ in #JOURNAL
{
set %arbol_encontrado #FALSE
gosub casa
return
}
goto diario
sub casa ;<==========================>
finditem %madera G_1
exevent drag #FINDID #FINDSTACK
wait 20
gosub comprobar
return
sub comprobar ;<==========================>
wait 10
if #WEIGHT > %peso
gosub recalear
return
sub recalear ;<==========================>
gosub comer
set %lugar %lugar + 1
ciclo:
finditem %libro_runas
set #LOBJECTID #FINDID
event macro 17
wait 30
if #CONTNAME = generic_gump
click %casax %casay
else
goto ciclo
wait 12s
if #CHARPOSX <> %posicionx_casa
goto ciclo
ciclo_2:
event macro 8 7
wait 10
finditem %madera C_ , #BACKPACKID
exevent drag #FINDID #FINDSTACK
exevent dropc %cofre
wait 20
finditem %madera C_ , #BACKPACKID || %madera G_2
exevent drag #FINDID #FINDSTACK
exevent dropc %cofre
wait 20
finditem %cofre
set #LOBJECTID #FINDID
event macro 17
wait 20
finditem %regs C_ , #BACKPACKID
if #FINDSTACK < 4
{
finditem %regs C_ , %cofre
exevent drag #FINDID 10
exevent dropc #BACKPACKID
wait 20
}
finditem %regs2 C_ , #BACKPACKID
if #FINDSTACK < 4
{
finditem %regs2 C_ , %cofre
exevent drag #FINDID 10
exevent dropc #BACKPACKID
wait 20
}
finditem %regs3 C_ , #BACKPACKID
if #FINDSTACK < 4
{
finditem %regs3 C_ , %cofre
exevent drag #FINDID 10
exevent dropc #BACKPACKID
wait 20
}
finditem %comida C_ , #BACKPACKID
if #FINDSTACK < 2
{
finditem %comida C_ , %cofre
exevent drag #FINDID 4
exevent dropc #BACKPACKID
wait 20
}
wait 10
if #WEIGHT > 100
goto ciclo_2
ciclo_3:
if %lugar < 4
{
finditem %libro_runas
set #LOBJECTID #FINDID
event macro 17
wait 30
if #CONTNAME = generic_gump
click %tala1x %tala1y
else
goto ciclo_3
wait 12s
if #CHARPOSX = %posicionx_tala1
return
else
goto ciclo_3
}
if %lugar > 6
{
finditem %libro_runas
set #LOBJECTID #FINDID
event macro 17
wait 30
if #CONTNAME = generic_gump
click %tala2x %tala2y
else
goto ciclo_3
wait 12s
if #CHARPOSX = %posicionx_tala2
return
else
goto ciclo_3
}
if %lugar > 3
{
finditem %libro_runas
set #LOBJECTID #FINDID
event macro 17
wait 30
if #CONTNAME = generic_gump
click %tala3x %tala3y
else
goto ciclo_3
wait 12s
if #CHARPOSX = %posicionx_tala3
return
else
goto ciclo_3
}
sub mover ;<==========================>
set %inicio_x #CharPosX
set %inicio_y #CharPosY
set %tiempo ( #SCnt + 1 )
mover:
move %mover_x %mover_y 1
if %tiempo < #SCnt
goto tiempo
if #CharPosX <> %mover_x || #CharPosY <> %mover_y
goto mover
tiempo:
if #CharPosX > ( %mover_x + 1 ) || #CharPosY > ( %mover_y + 1 )
gosub caminar
return
sub caminar ;<==========================>
ciclo_4:
event sysmessage * Buscando nueva ubicacion. *
set %random #random / 100
if %random < 3
goto ciclo_4
if %random = 3
{
set %inicio_x #charposx - %random
set %inicio_y #charposy - %random
move %inicio_x %inicio_y a 5s
}
wait 5
if %random = 4
{
set %inicio_x #charposx + %random
set %inicio_y #charposy + %random
move %inicio_x %inicio_y a 5s
}
wait 5
if %random = 5
{
set %inicio_x #charposx + %random
set %inicio_y #charposy
move %inicio_x %inicio_y a 5s
}
wait 5
if %random = 6
{
set %inicio_x #charposx - %random
set %inicio_y #charposy
move %inicio_x %inicio_y a 5s
}
wait 5
if %random = 7
{
set %inicio_x #charposx - %random
set %inicio_y #charposy + %random
move %inicio_x %inicio_y a 5s
}
wait 5
if %random >= 8
{
set %inicio_x #charposx + %random
set %inicio_y #charposy - %random
move %inicio_x %inicio_y a 5s
}
return
sub comer ;<=========================>
finditem %comida C_ , #BACKPACKID
set #LOBJECTID #FINDID
event macro 17
return

Pd: Macro de minar en proceso, xdd

Saludos!!!

**axel123** · 01-Sep-2014

q hacha magica?

**Tinerfe el grande** · 01-Sep-2014

Si no tienes un hacha mágica simplemente pon la ID de un hacha normal en:
set %hacha FSF_ASF

**axel123** · 05-Sep-2014

es muy dificil configurar y eso, osea no se como hacer eso xDD :/

**BlooD_Aeris** · 05-Sep-2014

Talar en 3 Pasos:

1: Configuracion.

Event SysMessage Situate en la esquina de la casa a la derecha de la puerta de entrada y pulsa ENTER.
a:
OnHotKey ENTER
gosub a
goto a

b:
Event SysMessage Situate JUSTO en frente del cofre y pulsa ENTER.
b1:
OnHotKey ENTER
gosub b
goto b1

1:
Event SysMessage Targetea el cofre.
set #TARGCURS 1
0:
if #TARGCURS = 1
goto 0
set *cofre #LTARGETID

c:
Event SysMessage Situate en la esquina de la casa a izquierda de la puerta de entrada y pulsa ENTER.
c1:
OnHotKey ENTER
gosub c
goto c1

d:
Event SysMessage situate en la posición de partida de la macro, pulsa ENTER, y habremos terminado.
d1:
OnHotKey ENTER
gosub d
goto d1

e:
Event SysMessage TODO CORRECTO. Ya puedes iniciar la macro
halt

sub a
set *esqdchax #CHARPOSX - 3
set *esqdchay #CHARPOSY + 3
wait 10
goto b

sub b
set *cofreposx #CHARPOSX
set *cofreposy #CHARPOSY
wait 10
goto 1

sub c
set *esqizdax #CHARPOSX + 3
set *ax *esqizdax - *esqdchax
set *ax *ax / 2
set *ax *esqdchax + *ax
wait 10
goto d

sub d
set *posinitx #CHARPOSX
set *posinity #CHARPOSY
wait 10
goto e

2: Movimiento.

Event SysMessage Macro de Talar escrita por Nilaween, iniciando:
;Si no vas a usar zona de talado, pon 0 en los dos valores.
;X e Y del punto que marca el vértice superior izquierdo del rectangulo de la zona de talado.
set %pArrIzdaX 0
set %pArrIzdaY 0

;Si no vas a usar la zona de talado, pon 9999 en los dos valores.
;X e Y del punto que marca el vértice inferior derecho del rectangulo de la zona de talado.
set %pAbaDchaX 9999
set %pAbaDchaY 9999

;################################################# #############################################
;################################################# #############################################

set %i *tiempo + 172800000
if %i < #SYSTIME
set *tiempo #SYSTIME

tile init

nuevaposicion:
set %cuadro 0
if ( #SYSTIME >= *horarepop || *horarepop = N/A ) && %pArrIzdaX <> 0 && %pAbaDchaX < 4000
{
set *horarepop #SYSTIME + 46800000
move *posinitx *posinity 0 300s
}

creandocuadro:
set %cuadro %cuadro + 1
set %ArIx #CHARPOSX - %cuadro
set %ArIy #CHARPOSY + %cuadro
set %AbDy #CHARPOSY - %cuadro
set %AbDx #CHARPOSX + %cuadro

set %ArIy %ArIy - 1
gosub buscador %ArIy %AbDy %ArIx 0 4
set %ArIx %ArIx + 1
gosub buscador %ArIx %AbDx 0 %AbDy 3
set %ArIy %ArIy + 1
set %AbDy %AbDy + 1
gosub buscador %AbDy %ArIy %AbDx 0 4
set %ArIx %ArIx - 1
set %AbDx %AbDx - 1
gosub buscador %AbDx %ArIx 0 %ArIy 3
goto creandocuadro

sub buscador
for % . %5 %1 %2
{
tile get %3 %4 2
if ( LEAVES IN #TILENAME || TREE IN #TILENAME || NEEDLES IN #TILENAME ) && %3 , %4 notIN *desechados0 && %3 , %4 notIN *desechados1 && %3 , %4 notIN *desechados2 && %3 , %4 notIN *desechados3 && %3 , %4 notIN *desechados4 && %3 , %4 notIN *desechados5 && %3 , %4 notIN *desechados6 && %3 , %4 notIN *desechados7 && %3 , %4 notIN *desechados8 && %3 , %4 notIN *desechados9 && %3 , %4 notIN *desechados10 && %3 , %4 notIN *desechados11 && %3 , %4 notIN *desechados12 && O'HII notIN #TILENAME && YEW notIN #TILENAME && %3 > %pArrIzdaX && %3 < %pAbaDchaX && %4 > %pArrIzdaY && %4 < %pAbaDchaY
gosub esperando %3 %4
}
return

sub esperando
set %tiempo #SYSTIME - *tiempo
while %tiempo > 46800000
set %tiempo %tiempo - 46800000
set %n %tiempo / 3600000
str left *desechados . %n 13
if #strRes < #SYSTIME || *desechados . %n = N/A
set *desechados . %n #SYSTIME + 46500000
set *desechados . %n *desechados . %n , _ , %1 , %2

if NEEDLES in #TILENAME
tile get %1 %2 3
if LEAVES in #TILENAME
tile get %1 %2 3
if #TILEZ = 0 && #TILECNT = 0 && #TILETYPE = 0 && TREE notIn #TILENAME
return

repeat
if %revision < #SYSTIME || %revision = N/A
{
set %revision #SYSTIME + 3600000
for %i 0 12
{
str left *desechados . %i 13
if #strRes < #SYSTIME
set *desechados . %i N/A
}
}
until TERMINADO_DE_TALAR In #SYSMSG

move %1 %2 1
set #LTARGETX %1
set #LTARGETY %2
set #LTARGETZ #TILEZ
set #LTARGETTILE #TILETYPE
set #LTARGETKIND 3

event sysMessage RECIBIDO TALADORA
set *posx #CHARPOSX
set *posy #CHARPOSY

goto nuevaposicion

3: Talar.

set %iracasa NO ; Pon SI si quieres que vaya a casa y guarde los logs, o NO de lo contrario.
set %comida PQD_MQE_FUD_OQE_YRD_YWI_AXI_VQE_BDF_TQE_KPE_QQD , _RQE_SQD_SPE_JQE_ZPE_IQE_YSD ;Pon el #LOBJECTTYPE de tu comida a continuacion, tras una _ .

;################################################# #############################################
;################################################# #############################################

set %tronco ZLK
set %peso #MAXWEIGHT - 20

init:
finditem *hacha C_ , #CHARID
if #FINDKIND = -1
{
finditem *hacha C_ , #BACKPACKID
if #FINDKIND = -1
{
Event SysMessage No se ha encontrado el hacha!
set #LOBJECTID YC
Event SysMessage Haz doble click sobre el hacha.
repeat
until #LOBJECTID <> YC
set *hacha *hacha , _ , #LOBJECTTYPE
goto init
}
}
set %hacha #FINDID

x:
repeat
if #SYSTIME => %tiemp || %tiemp = N/A
{
set %tiemp #SYSTIME + 4400
event sysMessage TERMINADO DE TALAR
}
if #SYSTIME >= %horacomida || %horacomida = N/A
{
set %horacomida #SYSTIME + 600000
finditem %comida C_ , #BACKPACKID
set #LOBJECTID #FINDID
event macro 17 0
}
until RECIBIDO_TALADORA In #SYSMSG
set %tiemp #SYSTIME

talando:
if #WEIGHT => %peso && %iracasa <> SI
gosub pacasa
set #LOBJECTID %hacha
set #TARGCURS 0
set %jEnd #JINDEX
event macro 17
target
event macro 22
set %tiempo #SYSTIME + 10000

controlando:
repeat
if #WEIGHT => %peso && %iracasa = NO
gosub dejando %tronco C_ #BACKPACKID dropg #CHARPOSX #CHARPOSY
if #SYSTIME > %tiempo
goto talando
until %jEnd <> #JINDEX
set %jStart %jEnd + 1
set %jEnd #JINDEX
for %i %jStart %jEnd
{
scanjournal %i
if AQUI_NO_HAY_NADA in #JOURNAL || PARECE_QUE_ES_INMUNE in #JOURNAL || NO_LO_ALCANZAS in #JOURNAL || ESO_ESTA_MUY_LEJOS in #JOURNAL || YOU_CANNOT_CHOP_SO in #JOURNAL
goto x
if PONES_EL_TRONCOS in #JOURNAL || A_TUS_PIES in #JOURNAL || PERO_NO_OBTIENES_MADERA_UTIL in #JOURNAL || YOUR_SKILL_IN in #JOURNAL
goto talando
}
goto controlando

sub pacasa
if *posy <= *esqdchay && *posx <= *ax
move *esqdchax *esqdchay
if *posy <= *esqdchay && *posx > *ax
move *esqizdax *esqdchay
move *cofreposx *cofreposy 0

gosub dejando %tronco C_ #BACKPACKID dropc *cofre

if *posy <= *esqdchay && *posx <= *ax
move *esqdchax *esqdchay
if *posy <= *esqdchay && *posx > *ax
move *esqizdax *esqdchay
move *posx *posy 0
return

sub dejando
finditem %1 %2 , %3
exevent drag #FINDID #FINDSTACK
wait 7
exevent %4 %5 %6
return

Es muy sencilla,configurala primero que todo,con la macro de configuracion,luego le das a movimiento y a talar,y a sacar troncos

Tema: Macro De Talar Urgente...

Herramientas

Buscar tema