buenas nesesito varias macros

[tramer]

buenas nesesito macro para mago osea que el mago se tire hechizos y tambn medite tambn nesesito una macro para subir nigromacia,spirit speak,boxeo y curar porfa vor no conosco muy bn las macros si las tienes se las pido de favor ponganlas gracias en especial que sean para easy uo o para uoloop para razor no porque no lo se utilizar bueno gracias

[wini13]

; ********************************************************************************
; ********************************************************************************
; Script Name: Spirit Speak
; Author: Blaizzer
; Version: 1.0
; Client Tested with: 7.0.8.3
; EUO version tested with: 1.5
; Shard OSI / FS: Ultima Alianza
; Private release: 28-01-11
; Public Release: 28-01-11
; Items needed: Manzanas por defecto
; Purpose: Sube Spirit Speak de ~30 a 100
; ********************************************************************************
; ********************************************************************************

; Type de la comida, manzanas por defecto
set %comida QQD

; No modificar a partir de aquí
; a no ser que sepas lo que estás haciendo

; Skill info
chooseskill Spir Real
set %skill_ini #SKILL

initevents:
goSub SS
goSub SysMsg
goSub info
goSub comer
goTo initevents

Sub SS
event macro 13 32
wait 2s

return

Sub SysMsg
set %seguridad 0
esperar:
if logras_contactar in #SysMsg
return
if your_skill in #SysMsg
return
if %seguridad = 300
return

set %seguridad %seguridad + 1

goTo esperar:

return

Sub info
set %skill_gain #SKILL - %skill_ini
setuotitle | Skill Inicial: %skill_ini | Skill Actual: #skill | P. Ganados: %skill_gain

return

Sub comer
finditem %comida c_ , #BACKPACKID
set #LOBJECTID #FINDID
event macro 17

return

[wini13]

; ------------------------------------------------------
; Macro de Tirar Magia/Medit para UA-Sphere (Sphere 0.56b-Nightly)
; Creado por: darksplit el 08/04/2010
; Ultima edición: N/A
; Modificaciones de: N/A
; ------------------------------------------------------
;
;
; Explicación:
; Se trata de una Macro para Tirar Magia Meditando y reponerse fácilmente
; desde un contenedor. Sólo tienes que abrir el contenedor donde están los regs,
; seleccionar la persona a la que van dirigidos los hechizos y la macro hará el resto.
; Cogerá siempre 100 regs de cada.
; Gastará siempre 20 de maná antes de empezar a meditar
; Para los usuarios más avanzados, dejo las variables a continuación
; por si se quiere poner que gaste más antes de meditar, y por si queréis coger más regs.
;
; ==================================
set %managastado #MAXMANA - 1 ; Este número simboliza el maná gastado máximo antes de meditar
set %numeroregs 200 ; Número de regs que cogerá para reponerse cada vez.
; ==================================

chooseskill mage real
set %skillinimagia #skill
chooseskill medi real
set %skillinimedit #skill
set #sysmsgcol 0000
event sysmessage Iniciando Macro...
event sysmessage
set #targCurs 0

configurar:
if %confp = 1 || %confp = N/A
{
set #sysmsgcol 1264
setuotitle Abre el contenedor donde estan los Regs.
event sysmessage ================
event sysmessage Abre el contenedor de Regs
event sysmessage Presiona la tecla ESC.
event sysmessage ================
set %confp 2
goto TESC
}
if %confp = 2
{
set #sysmsgcol 1264
setuotitle Selecciona tu objetivo
event sysmessage ================
event sysmessage Selecciona tu objetivo
event sysmessage ================
set #sysmsgcol 0000
set #targCurs 1
wait 1s
goto CURSOR
}

CURSOR:
if #TARGCURS = 1
{
goto CURSOR
}
if #TARGCURS = 0
{
set %objetivo #LTARGETID
gosub uotitle
goto loop
}
goto CURSOR


TESC:
onHotKey ESC
{
set %idcaja #LOBJECTID
goto configurar
}
goto TESC

scanjournal 1

loop:
wait 40
repeat
{
gosub check
set #LTARGETID %objetivo
event macro 15 7
wait 8
event macro 22 0
gosub uotitle
}
until #mana <= %managastado
repeat
{
gosub meditar
}
until #mana = #int
goto loop

sub uotitle
wait 10
chooseskill mage real
set %skillmagiaahora #SKILL
chooseskill medi real
set %skillmeditahora #SKILL
finditem KZF C_ , #BACKPACKID
set %cuantogarlic #FINDSTACK
finditem WZF C_ , #BACKPACKID
set %cuantonight #FINDSTACK
setuotitle || Magia | Ini: %skillinimagia | Actual: %skillmagiaahora || Medit | Ini: %skillinimedit | Actual: %skillmeditahora || Regs | Garlic: %cuantogarlic | Night: %cuantonight ||
return

sub meditar
event macro 13 46
if pierdes in #journal
{
gosub meditar ; Meditamos hasta que no perdamos la concentración
}
if trance in #journal
repeat
{
wait 40
event macro 13 46 ; Aseguramos que mientras meditemos no perdamos la concentración. Así que cada 2 segundos meditará.
}
until #mana = #int
return


sub check
finditem WZF C_ , #BACKPACKID
if #FINDCNT = 0
{
gosub abrircaja
wait 5
set %reg WZF
gosub coger
}
finditem KZF C_ , #BACKPACKID
if #FINDCNT = 0
{
gosub abrircaja
set %reg KZF
gosub coger
}
return

sub abrircaja
set #LOBJECTID %idcaja
event macro 17 0
wait 10
return

sub coger
finditem %reg C_ , %idcaja
exevent drag #FINDID %numeroregs
wait 10
exevent dropc #BACKPACKID
wait 10
return

[wini13]

; ********************************************************************************
; ********************************************************************************
; Script Name: Nigromancia
; Author: Blaizzer
; Version: 1.0
; Client Tested with: 7.0.8.3
; EUO version tested with: 1.5 (181)
; Shard OSI / FS: Ultima Alianza
; Private release: 09-02-11
; Public Release: 09-02-11
; Items needed: Manzanas y peras por defecto y
; un arma equipada
;
; Purpose: Sube Nigromancia de ~30 a 100
; ********************************************************************************
; ********************************************************************************

set %comida QQD_YSD

initevents:
goSub MA
goSub meditar
goTo initevents

Sub MA
hechizo:
if #MANA < 15
return

msg .nigro 4 $
wait 2s
goSub checkSave
goSub comer
goTo hechizo

return



Sub meditar
esperar:
if #MANA < #MAXMANA
{
event macro 13 46
wait 2s
goSub checkSave
goTo esperar
}

return



Sub checkSave
if comienza_la in #SYSMSG
wait 40s

return



Sub comer
findItem %comida C_ , #BACKPACKID
if #findcnt > 0
{
set #LOBJECTID #FINDID
event macro 17
}

return

[wini13]

;==================================
; Script Name: Entrenar Curar
; Author: Trokolo
; Version: 1.8
; Client Tested with: 2.0.3
; EUO version tested with: 1.5 Version 130
; Shard: Ultima Alianza
; Release: 15/06/08
; Purpose: Heal
;==================================
;Configurar:
;Para usar esta macro se precisa un arma que incremente tu STR
;Poner en vuestra mochila un bidon de agua
;En el UO escribir .guardar_uid 1 y seleccionar el arma
event sysmessage Macro Ofrecida por Trokolo
wait 20

chooseskill heal real
set %skillini #SKILL
set %bidon WEE_VEE_QEE_TEE
curar:
set %skillinc #SKILL - %skillini
setuotitle | Skill Inicial:: %skillini | Skill Actual: #SKILL | Incremento: %skillinc |
msg .usar_uid 1 $ ;Arma Defensa +9
wait 10
msg .vendas $
wait 5
event macro 23 0
wait 10
scanjournal
if te_aplicas_las_vendas_pero_fallas in #journal || No_logras in #journal || no_necesitas in #journal
{
wait 2s
goto curar
}
msg .desarmarse $ ;Te desarmas
wait 15s
finditem AMF ;Vendas sucias
set #LOBJECTID #FINDID
event macro 17 0 0 ;LastObject
wait 20
finditem %bidon C_ , #BACKPACKID
set #LTARGETID #findid
event macro 22 0
goto curar:

[wini13]

para boxeo tienes k subirlo con un amigo con poca armor
con k le pegues y se valla curando sobra

[wini13]

visto que no contestas en el post si necesitas alguna mas avisame