Por si no esta deshabilitada est ttiene buena pinta 
:
Código:
;RoadkillsCooking.txt Copyright 13Jun03 by Roadkill
;ver 1.1 30 Nov 03, fixed missing commas and ingot type
;Notes:
;1. This script will 0-GM you in Cooking. I recommend you buy cooking from an NPC up to 30ish
; then use script up to what you want. You can make savage paint at 80.
;2. You can use either Ribs or fishsteaks. It takes about 20,000 fishsteaks 0-80.
;3. You only gain skill on cooking success; you use up a steak or so when you fail. Some
; folks told me that if you cook 1000 or more at a time, you will get the gains all
; at once. I did NOT find this to be true-- the most I observed was about .3, which you
; can also gain by cooking 20 - 40 fishsteaks.I have given you a variable to set, %cookamt
; to tell it how many to try cooking at once, I recommend leaving it at 20.
;4. You must be standing within reach of a SECURE container you have access to.
; This container MUST CONTAIN a BAG OR PACK, inside which you must have your raw materials,
; Fishsteaks or Ribs.
;5. You must be standing near a fire; this can be a HEATING STAND on the ground, lit, or a forge, etc
;6. You must have either the tinker skill to make skillets (30min, I ask for 35)
; and have the tinkers tools/ingots on you,OR you must have skillets in your mainpack
;7. You must set your windows screen resolution to be at least 1024x768, or change the
; positions I open stuff and paperdoll so I can drop fishsteaks in your pack
;8. MOST IMPORTANT STEP!! I use "make last" for tinkering and cooking,
; so before starting script please cook one of what you are making (ribs or fishsteaks),
; and if you are tinkering your skillets, make one of them! THEN PRESS PLAY!
;===========CONFIGURATION: Recommend you leave it, copy/paste, and press play!===========
set %cookamt 20
set %delay 30 ;change this to higher if slow connectin, 30= 1.5sec
;===================================================================================
initevents
GOSUB CookingSetup
start:
finditem DND C_ , %mainpack
if #findkind = -1 3
gosub makeskillet
wait 2s
goto start
set #lobjectid #findid
event macro 17
wait 2
finditem %rawitemtype C_ , %mainpack
if #FINDKIND = -1
GOSUB moveitemtoPos1 %rawitemtype 900 650 %cookamt
click 334 462
wait 20
if #weight > #maxweight
{
finditem %cookeditemtype C_ , %mainpack
set %cookeditemID #findid
finditem %secureSubpack
set #findmod 25_7
GOSUB moveitemtoPos1 %cookeditemID #findx #findy 0
}
goto start
;----------------------
SUB CookingSetup
event macro 31
wait %delay
event macro 8 1
wait %delay
contpos 760 425
wait %delay
event macro 8 2
wait %delay
contpos 650 0
wait %delay
event macro 8 7
wait %delay
contpos 580 380
wait %delay
set %mainpack #contid
Display yesno Are your paperdoll and mainpack open and placed to the right?$
+ If not, please open them and move them to right, both visible,$
+ then push play--and PAPERDOLL MUST BE TOTALLY ONSCREEN!$
if #DISPRES = No
Pause
set #NEXTCPOSX 580
set #NEXTCPOSY 150
Display ok Open the SECURE containing your SUBPACK that holds your raw fish or ribs$
+ and place it to the right so it doesn't cover$
+ the paperdoll, mainpack and gameplay area.$
+ Press ENTER to continue.$
keyloop1:
onhotkey enter
goto continuesetup1
goto keyloop1
continuesetup1:
set %secure #CONTID
Display ok Now open the bag that contains the RAW FISH or RIBS$
+ This should be a bag INSIDE the secure.$
+ Please make sure you have enough raw stuff to cook.$
set %oldcontid #CONTID
set #NEXTCPOSX 780
set #NEXTCPOSY 200
getbagid1:
if #CONTID = %oldcontid
goto getbagid1
wait %delay
wait %delay
set %secureSubPack #CONTID
getrawtype1:
DISPLAY OK Now please target the RAW FISHSTEAKS or RIBS in the$
+ SECURE SUBPACK that you will cook$
SET #TARGCURS 1
getrawtype2:
if #targcurs = 1
goto getrawtype2
FINDITEM #LTARGETID
SET %rawitemtype #FINDTYPE
set %cookeditemtype HND
IF %rawitemtype = VRD
set %cookeditemtype YRD
;check for pans or tinker skill/supplies
chooseskill cook
IF #SKILLLOCK <> UP
{
DISPLAY OK It looks like your cooking skill is NOT set to raise$
+ Please change it to UP then hit play
PAUSE
}
finditem DND C_ , %mainpack
IF #FINDKIND = 0
return
chooseskill tink
IF #skill < 35
{
DISPLAY OK It looks like your tinker skill is NOT high enough$
+ to make skillets. Please buy some then restart script$
HALT
}
FINDITEM JTL C_ , %mainpack
IF #FINDKIND
{
DISPLAY OK I can't find any tinker tools in your mainpack.
+ Please buy some then restart script$
HALT
}
FINDITEM ENK C_ , %mainpack
IF #FINDKIND
{
DISPLAY OK I can't find any ingots in your mainpack.
+ Please get some then restart script$
HALT
}
RETURN
;----------------
sub moveitemtoPos1
set %_item %1
set %_x %2
set %_y %3
set %_amount %4
finditem %_item C
if #findkind
halt
event drag #FINDID
; wait %delay
WAIT 15
if #FINDSTACK > 1
{
if %_amount = 0 || #findstack < %_amount
msg $
if %_amount > 0
msg %_amount $
}
wait 10
click %_x %_y p
wait 10
return
;--------
sub makeskillet
finditem jtl
if #findkind
halt
set #lobjectid #FINDID
event macro 17
wait 5
click 334 463
wait 5
return
Permisos de publicación
Citar
