Vamos a ver ^^
Tu tienes la siguiente macro
Código:
; Macro by Alex (Ultima Alianza)
; Para hacer dagas, hacerlas un lote y después guardarlo o hacerlo tiquets.
; Necesitamos un cofre/bolsa/contenedor donde tengamos los lingotes y martillos y en ese mismo donde dejar los lotes en caso de no querer tiquets,
; Debemos estar al lado de: una yunke, el cofre/bolsa/contenedor, y en el caso que queramos, al lado de una papelera de reciclage.
; Primero tenemos que poner cuantos lingotes queremos coger cada vez,
; No es recomndable poner muchos por si tenemos sobrepeso.
; Al empezar deberemos configurar el Cofre/bolsa/contenedor y un punto de nuestra mochila.
; Los pasos se explican en el UO al darle a empezar, fijaros en la barra superior del UO.
; Una vez configurado la macro empezará sola a separar, fundir y guardar.
; Macro de herrero para funcionar en Ultima Alianza
; Poner aquí la cantidad de hierro que deberá coger cada vez que tenga poco.
;--------------------------
set %cantidad 100
;--------------------------
; Quieres hacer tiquets el lote de dagas? escribe aquí si o no.
;--------------------------
set %tiquets si
:--------------------------
initevents
set %confp 1
set %lingote RMK
chooseskill blac real
set %skillini #skill
set %lotex 113
set %lotey 62
set %idlote CKF
set %movx 268
set %movy 64
set %dagax1 271
set %dagay1 67
set %dagax2 250
set %dagay2 67
set %dagax3 66
set %dagay3 63
set %dagax4 135
set %dagay4 64
set %pap BKF
set %gumpx1 94
set %gumpy1 172
set %gumpx2 305
set %gumpy2 343
set %martillo TLH_GBG
configurar:
if %confp = 1
{
Event sysmessage Abre el cofre en el que tienes los lingotes de hierro, manten el cursor sobre el.
event sysmessage Y presiona la tecla ESC
setuotitle Abre el contenedor que contiene los lingotes y luego manten el cursor en el y presiona ESC
set %conf 1
set %confp 2
goto TESC
}
if %confp = 2
{
setuotitle Pon el cursor encima de la mochila del paperdoll y presiona ESC
event sysmessage Pon el cursor encima de la mochila del Paperdoll, recuerda no mover el paperdoll.
event sysmessage Y presiona la tecla ESC
set %conf 2
goto TESC
}
TESC:
onHotKey ESC
{
if %conf = 1
{
set %cofre #LOBJECTID
set %cofrex #CURSORX
set %cofrey #CURSORY
goto configurar
}
if %conf = 2
{
set %dejarx #CURSORX
set %dejary #CURSORY
set %tot 0
set %vez 0
set %fin 0
set %totlot 0
goto empezar
}
}
goto TESC
empezar:
findItem %martillo C_ , #BACKPACKID
if #FINDSTACK = 0
{
gosub martillos
}
set #LOBJECTID #FINDID
event macro 17
wait 20
KEY ESC
findItem %lingote C_ , #BACKPACKID
if #FINDSTACK > 12 || #FINDCNT > 3
{
goto hacerdagas
}
findItem %lingote C_ , %cofre
if #FINDSTACK < 10
{
set %fin 1
gosub finalizar
}
event drag #FINDID
wait 10
msg %cantidad
msg $
click %dejarx %dejary p
set %tothierro %tothierro + %cantidad
wait 10
hacerdagas:
set %skillinc #SKILL - %skillini
findItem %martillo C_ , #BACKPACKID
if #FINDSTACK = 0
{
gosub martillos
}
set #LOBJECTID #FINDID
event macro 17
wait 10
KEY ESC
findItem TSF C_ , #BACKPACKID
set %totdagas #FINDCNT
if #FINDCNT > 14
{
goto hacerlote
}
findItem %lingote C_ , #BACKPACKID
if #FINDSTACK < 12
{
if #FINDCNT < 2 || %prueba > 5
{
set %prueba 0
goto empezar
}
else
{
if #FINDCNT < 3
{
set %prueba %prueba + 1
}
}
}
set #LOBJECTID #FINDID
event macro 17
wait 20
click %dagax1 %dagay1 f
wait 20
click %dagax2 %dagay2 d
wait 20
click %dagax3 %dagay3 d
wait 20
click %dagax4 %dagay4 d
wait 20
setuotitle Macro de Herrero | S.Inicial: %skillini | S. Actual: #SKILL | S. Inc: %skillinc | Dagas: %totdagas | Hierro cogido: %tothierro | Lotes: %totlot
goto hacerdagas
hacerlote:
findItem %martillo C_ , #BACKPACKID
if #FINDSTACK = 0
{
gosub martillos
}
findItem %lingote C_ , #BACKPACKID
if #FINDSTACK = 0
{
findItem %lingote C_ , %cofre
if #FINDSTACK <> 0
{
event drag #FINDID
wait 10
msg 2 $
click %dejarx %dejary p
wait 10
setuotitle Macro de Herrero | S.Inicial: %skillini | S. Actual: #SKILL | S. Inc: %skillinc | Dagas: %totdagas | Hierro cogido: %tothierro | Lotes: %totlot
}
else
{
set %fin 1
gosub finalizar
}
}
set #LOBJECTID #FINDID
event macro 17
click %lotex %lotey d
wait 10
guardarlote:
findItem %martillo C_ , #BACKPACKID
if #FINDSTACK = 0
{
gosub martillos
}
if %tiquets = no
{
findItem %idlote C_ , #BACKPACKID
if #FINDSTACK > 0
{
event drag #FINDID
wait 10
click %cofrex %cofrey p
set %totlot %totlot + 1
goto guardarlote
}
goto empezar
}
if %tiquets = si
{
findItem %idlote C_ , #BACKPACKID
if #FINDCNT > 0
{
findItem %pap G_3
if #FINDSTACK = 0
{
set %fin 3
goto finalizar
}
else
{
set #LOBJECTID #FINDID
event macro 17
wait 20
click %gumpx1 %gumpy1 f
wait 20
click %gumpx2 %gumpy2 f
findItem %idlote C_ , #BACKPACKID
set #LTARGETID #FINDID
event macro 25
set #lTargetKind 1
event macro 22
event macro 22
set #lTargetKind 1
wait 10
click %gumpx2 %gumpx2 r
set %totlot %totlot + 1
setuotitle Macro de Herrero | S.Inicial: %skillini | S. Actual: #SKILL | S. Inc: %skillinc | Dagas: %totdagas | Hierro cogido: %tothierro | Lotes: %totlot
goto guardarlote
}
}
goto empezar
}
sub martillos
{
findItem %martillo C_ , %cofre
if #FINDSTACK = 0
{
set %fin 2
gosub finalizar
}
event drag #FINDID
wait 10
set %dejar2x %dejarx + 15
set %dejar2y %dejary + 15
click %dejar2x %dejar2y p
set #LOBJECTID #FINDID
wait 20
event macro 17
wait 10
KEY ESC
findItem %martillo C_ , #BACKPACKID
if #FINDSTACK = 0
{
gosub martillos
}
return
}
sub finalizar
{
if %fin = 1 || %fin = N/A
{
display OK Macro terminada!$No se han encontrado los lingotes de hierro necesarios!
}
if %fin = 2
{
display OK Macro terminada!$No tienes martillo!
}
if %fin = 3
{
display OK Macro terminada!$Has puesto que quieres hacer tiquets los lotes, pero no estas suficientemente cerca$de una papelera de reciclage!
}
halt
return
}
Las locations que tienes que cambiar son los numeros que te he pintado en rojo, y ahora te voy a explicar como cambiarlos.
daga1 no hemos de cambiarlo ya que indica la localizacion de la flecha a la derecha en el menu de fabricacion y siempre ta en el mismo sitio
daga2 corresponde a la opcion "Armas" en el menu de fabricacion. Para saber donde "está", abre el menu de fabricacion ( 2click en el martillo, click lingotes ), dale 1 click a la flecha de la derecha y pon el raton encima de "Armas". Sin mover el raton, en el EasyUO en la barra de abajo de todo donde aparecen unos numero, has de fijarte en la 4ª columna, unos numeros de estilo 250/60. El primero corresponde a daga2x y el 2º a daga2y.
daga3 corresponde a la opcion "Swords & Blades" en el menu fabricacion y puedes encontrar la location de la misma forma que la anterior.
daga4 corresponde a la opcion "daga" en el menu de fabricacion y mas de lo mismo
Espero haberte servido de ayuda, si tienes algun problema o algo pos me dices