Como guardar el diario

[Joseph]

Hola, ¿hay alguna forma de guardar el diario completo? estoy buscado por la web pero no encuentro nada al respecto, gracias.

Un saludo
JoSePh

[macca]

hay una opcion en el UO.cfg ( si no me equivoco) en la cual puedes poner que te guarde el diario. Te dejo el link de la FAQ por si aparece ahi:

Configuracion de UO.cfg

[Joseph]

Cierto, ahí viene un comando, SaveJournal=off, que habrá que poner on, también en el menú de opciones del juego puedes decirle que te grabe un archivo, o en formato de texto o en formato unicode, que ni idea lo que es, ¿un solo código?, con todo lo que acontece en el diario, pero lo que no encuentro, es ¿donde esta el archivo?, estoy buscando por la red, pero nada, gracias por tu ayuda.

Un saludo

[Terrikate]

Lo tienes en el mismo tema que te indicó macca.

JournalFile= <--- El Archivo donde se Guarda el Journal (Diario) Si teneis esa Opcion ON.

Tienes que poner dónde quieres que te lo guarde, en que fichero y lugar.

journal.txt (te lo debería guardar en la carpeta del UO o donde tengas el cliente)
c:\journal.txt (te lo guardará en C:\)

Saludos.

[Joseph]

Mil perdones, se me paso esa linea, muchas gracias a los dos.

Un saludo

[Joseph]

Antes de nada perdonar mi torpeza, pero no me funciona, no me crea ningún archivo, algo hago mal, abro el uo.cfg de la carpeta principal, sigo lo pasos, pongo el on, creo la linea, incluso tambien me voy a los archivos uo.cfg de cada pj, hago lo mismo, pero no me crea el archivo. ¿que puede ser?

[Joseph]

Solucionado, el comando de la FAQ no es correcto, JournalSaveFile=ruta\diario.log, ahora si me graba el diario.

Un saludo, y gracias por vuestro tiempo.

[mongusensei]

Muchas gracias por sacar el tema. Hacía tiempo que yo también andaba detrás de esto.

Un saludo.

[Joseph]

De nada, es un placer haber servido de ayuda.

Saludos

[mongusensei]

Vuelvo a rescatar un tema debido a una inquietud. Se puede hacer de alguna manera que aparezca la hora en el diario? Se me guarda todo perfectamente, pero estaría bien saber a qué hora se ha desconectado el pj o lo que sea.

Gracias y un saludo.

[Joseph]

Por si a alguien le interesa os dejo una macro que graba el diario con la hora incluida.

; Author: TIM (timginter)

Inicio:
gosub menuBody
set %jEntry #jIndex
set %listIndex 0
mainLoop:
if ( %jEntry < #jIndex || %jEntry = N/A )
{
set %scanLine #jIndex - %jEntry
scanJournal %scanLine
set %journal #journal
menu get filter_spam
set %filterSpam #menuRes
menu get filter_spells
set %filterSpells #menuRes
if %filterSpells = #true
{
str pos %journal : 1
str del %journal 1 #strRes
set %spellCheckStr #strRes
}
if ( %journal <> %lastEntry || %filterSpam = #false ) && ( %spellCheckStr notIn %wordsOfPower || %filterSpells = #false )
{
set %lastEntry %journal
str count %journal _
while #strRes > 0
{
str pos %journal _
set %underscorePos #strRes
str del %journal #strRes 1
str ins #strRes #spc %underscorePos
set %journal #strRes
str count %journal _
}
set %listIndex %listIndex + 1
gosub time
set %line_ . %listIndex %time , #spc , %journal
menu list add journal %line_ . %listIndex
menu list select journal %listIndex
}
set %jEntry %jEntry + 1
}
if #menuButton <> NONE
{
gosub #menuButton
set #menuButton NONE
}
goto mainLoop

sub save
menu get path
set %file #menuRes
gosub time
set %listIndex %listIndex + 1
set %line_ . %listIndex %time , #spc , SAVING , #SPC , TO: , #SPC , %file
menu list add journal %line_ . %listIndex
menu list select journal %listIndex
set %jEntry %jEntry + 1
if %saveIndex = N/A
{
set %saveIndex 1
}
set %saveGroupIndex 1
set %groups ( %listIndex - %saveIdex ) / 20
event sysMessage %groups
saveLoop:
set %params %listIndex - %saveIndex
if %params > 20
{
set %params %saveIndex + 18
set %lastParam %saveIndex + 19
set %saveGroup . %saveGroupIndex
for %save_i %saveIndex %params
{
set %saveLine %line_ . %save_i
set %saveGroup . %saveGroupIndex %saveGroup . %saveGroupIndex , #SPC , %saveLine , #SPC , >> , #SPC , %file , #SPC , && , #SPC , echo
}
set %saveLine %line_ . %lastParam
set %saveGroup . %saveGroupIndex %saveGroup . %saveGroupIndex , #SPC , %saveLine , #SPC , >> , #SPC , %file
set %saveGroupIndex %saveGroupIndex + 1
set %saveIndex %params + 1
goto saveLoop
}
else
{
set %params %params - 1
set %params %saveIndex + %params
set %lastParam %saveIndex + %params + 1
set %saveGroup . %saveGroupIndex
for %save_i %saveIndex %params
{
set %saveLine %line_ . %save_i
set %saveGroup . %saveGroupIndex %saveGroup . %saveGroupIndex , #SPC , %saveLine , #SPC , >> , #SPC , %file , #SPC , && , #SPC , echo
}
set %saveLine %line_ . %lastParam
set %saveGroup . %saveGroupIndex %saveGroup . %saveGroupIndex , #SPC , %saveLine , #SPC , >> , #SPC , %file
}
for %save_i 1 %saveGroupIndex
{
execute cmd.exe /c echo %saveGroup . %save_i
}
gosub time
set %listIndex %listIndex + 1
set %line_ . %listIndex %time , #spc , SAVING , #SPC , DONE
menu list add journal %line_ . %listIndex
menu list select journal %listIndex
set %jEntry %jEntry + 1
return

sub left
if %width > 300
{
gosub menuBody -100 0
}
gosub rewriteList
return

sub right
if %width < 1200
{
gosub menuBody 100 0
}
gosub rewriteList
return

sub rewriteList
menu list clear journal
for %restoreList_i 1 %listIndex
{
menu list add journal %line_ . %restoreList_i
}
menu list select journal %listIndex
return

sub closed
stop
return

sub time
set %time #time
str ins %time : 5
str ins #strRes : 3
set %time [ , #strRes , ]
return

sub menuBody
menu Clear
menu Font Name Comic Sans MS
menu Window title TIM's Journal
menu Window color black
menu Font Name Verdana
menu Font color green
menu Font bgcolor black
menu Font size 8
if %width = N/A
{
set %width 500
}
if %height = N/A
{
set %height 120
}
set %yCoordinate 5
if %0 > 0
{
set %width %width + %1
}
menu list create journal 5 %yCoordinate %width %height
menu Font Name Comic Sans MS
set %yCoordinate %yCoordinate + %height
set %yCoordinate %yCoordinate + 5
if %filterSpam = N/A || %filterSpells = N/A
{
set %filterSpam #false
set %filterSpells #false
}
menu check filter_spam 5 %yCoordinate 100 20 %filterSpam Filter spam?
menu check filter_spells 100 %yCoordinate 100 20 %filterSpells Filter spells?
set %yCoordinate %yCoordinate + 20
menu button save 5 %yCoordinate 100 20 SAVE
menu edit path 110 %yCoordinate 150 C:\journal.txt
menu button left 265 %yCoordinate 20 20 <
menu button right 287 %yCoordinate 20 20 >
set %yCoordinate %yCoordinate + 25
set %windowSize %width + 10
menu Window Size %windowSize %yCoordinate
menu Show
set #menuButton NONE
return


Saudos

[Dama Antigua]

donde lo guarda??????

[Joseph]

Abajo, en la ventana que te sale, al lado de save te pone la ruta, c:\journal.txt, te lo guarda cuando le picas a save, mientras lo tienes en la ventana.

Saludos

[mongusensei]

Gracias Joseph, yo ya estoy utilizándolo.

Un saludo.

[Metapod]

Si no te aclaras mucho, es trabajo de orientales pero podras guardarlo imprimiendo pantalla de lo que le interese.