[MACRO] Artesano (ganzuas y botellas)

[Aloisia]

Bueno, les dejo una macro para subir artesania, que espero les sirva. Puesto que no me acuerdo de a que nivel de habilidad se podía hacer cada cosa, no se exactamente cuando cambia el menú, así que habrá que configurar una pequeña cosilla:

set %pala 235 ;aqui se pone la coordenada x de la pala en el menu (175 si 4ª y 235 si 5ª)

Básicamente, dependiendo de la posición en que nos aparezca la pala en el menu de artesano, tendremos que poner en vez del 235, el número correspondiente a la coordenada X (la primera de las dos que marca el easyuo) de la posicion de la pala en nuestro menú (si está en posición 4ª, pondremos 175, si está en posición 5ª, 235).
Otro apunte, no se a que habilidad se empiezan a hacer ganzuas. Mientras no podamos hacer ganzuas, para hacer botellas habrá que seleccionar en la macro, al principio, la opción 1.- Hacer ganzuas. Nos hará botellas, hasta llegar a la habilidad necesaria para las ganzuas, en cuyo caso seguirá haciendo ganzuas.

;==================================
; Script: Artesano
; Autor: Aloisia
; Version Easyuo: 1.5, 148
; Version: 1.0
; Cliente: 2.0.3
; Fecha del script: 08 Mayo 2010
; Finalidad: Hace ganzuas o botellas.
;==================================
set %pala 235 ;aqui se pone la coordenada x de la pala en el menu (175 si 4ª y 235 si 5ª)
set %hierro RMK
set %herramienta GTL
set %objeto NWH_WUF
initevents
set %confp 0

configurar:
if %confp = 0
{
	Event sysmessage Pulsa 1 para hacer ganzuas.
	event sysmessage O 2 para hacer botellas.
	set %confp 1
	goto ELECCION
}
if %confp = 1
{
	Event sysmessage Abre el contenedor donde tienes el hierro.
	event sysmessage Y presiona la tecla ESC.
	set %conf 1
	set %confp 2
	goto TESC
}
if %confp = 2
{
	event sysmessage Abre el contenedor donde se encuentran las herramientas.
	event sysmessage Y presiona la tecla ESC
	set %conf 2
	set %confp 3
	goto TESC
}
if %confp = 3
{
	event sysmessage Abre el contenedor donde dejar el producto.
	event sysmessage Y presiona la tecla ESC
	set %conf 3
	goto TESC
}

ELECCION:
onHotKey 1
{
   msg $
   set %conf 1
   set %menu 1
   event sysmessage Haremos GANZUAS.
   GoTo configurar:
}
onHotKey 2
{
   msg $
   set %conf 1
   set %menu 2
   event sysmessage Haremos BOTELLAS.
   GoTo configurar:
}
GoTo ELECCION:

TESC:
onHotKey ESC
{
	if %conf = 1
	{
		set %cofre #LOBJECTID
		goto configurar
	}
	if %conf = 2
	{
		set %bolsa #LOBJECTID
		goto configurar
	}
	if %conf = 3
	{
		set %destino #LOBJECTID
		goto comienzo:
	}
}
goto TESC

comienzo:
finditem %objeto c_ , #BACKPACKID
IF #findStack > 40
{
   GoSub dejarobjeto
}
finditem %hierro c_ , #BACKPACKID
IF #findStack < 15
{
GoSub cogerhierro
}
finditem %herramienta c_ , #BACKPACKID
IF #findcnt < 2
{
GoSub cogerherramienta
}
finditem %herramienta c_ , #BACKPACKID
set #LOBJECTID #FINDID
event macro 17
wait 20
click %pala 65 d
wait 20
if %menu = 1
{
   click 60 60 d
}
if %menu = 2
{
    click 105 60 d
}
wait 2s
GoTo comienzo:

Sub cogerhierro
finditem %hierro c_ , %cofre
IF #findStack < 100
{
   msg Parando macro por falta de hierro
   wait 10
   msg $
   halt
}
IF #weight > 100
{
   GoSub dejarobjeto
   if #weight > 100
   {
      msg Parando macro por exceso de peso
      wait 10
      msg $
      halt
   }
}
finditem %hierro c_ , %cofre
Exevent Drag #findid 100
wait 10
Exevent Dropc #BACKPACKID
wait 20
return

Sub cogerherramienta
finditem %herramienta c_ , %bolsa
IF #findcnt < 1
{
   msg Parando macro por falta de herramientas
   wait 10
   msg $
   halt
}
Exevent Drag #findid
wait 10
Exevent Dropc #BACKPACKID
wait 20
return

Sub dejarobjeto
wait 3s
finditem %objeto c_ , #BACKPACKID
Exevent Drag #findid #findstack
wait 10
Exevent Dropc %destino
wait 20
return

[Ibrahimovic 9]

Aloisia yo quiero que hagan engranajes me podrias ayudar , Gracias

[darksplit]

no la etngo a la vista la macro,
pero tienes que cambiar coordenadas del menu y listo.

[Aloisia]

Mira, tendrías que poner en:

set %pala 235 ;aqui se pone la coordenada x de la pala en el menu (175 si 4ª y 235 si 5ª)

la coordenada del grupo donde están los engranages, y luego, dependiendo de donde te salgan los engranages (en primera o segunda posición), eliges el 1 o el 2 cuando inicias la macro.

Es que ahora no puedo entrar con el artesano, pero si quieres dime en que posición del menu de artesano tienes que hacer doble click para que te salgan los engranages en el menú, y en que posición salen los engranages, y te cambio la macro.

[Ibrahimovic 9]

Me sale las Partes ( Numero 3 ) y Los engranajes ( Numero 1 ) , Y No compres cuca que esta noche cuando yo este Online te la regalo... , Tengo que irme a trabajar ahora

[Aloisia]

Cambia esta línea en la macro:

set %pala 235 ;aqui se pone la coordenada x de la pala en el menu (175 si 4ª y 235 si 5ª)

por esto:

set %pala 115 ;aqui se pone la coordenada x de la pala en el menu (175 si 4ª y 235 si 5ª)

Inicia la macro y pulsa 1 cuando te pregunte (corresponde a ganzuas, pero tu no te preocupes). Si no te va asi, hazmelo saber.

[Ibrahimovic 9]

Me funciona pero se lleva muchisimas veces el menu a la mano y cuando esta entero de peso se para la macro por mucho peso jajaja
Esta Tarde-Noche aver si lo arreglamos mejor por msn , Gracias

[Aloisia]

¿No tendrás puesto el Razor? Las macros de fabricacion de objetos de Easyuo no se pueden usar con Razor, porque sino pasa eso.

Lo del peso es porque falta poner el Type de los engranajes para que los guarde. Tienes que mirar el Type de los engranajes, y añadirlo en esta linea:

set %objeto NWH_WUF

de tal forma que te quedaría:

set %objeto NWH_WUF_XXX

donde XXX es el Type de los engranajes. Para saber el TYPE de las doble click a un engranje, y en el Easyuo, en el menú de la derecha, miras las 3 letras del #LOBJECTTYPE.

[Bobypowa]

Que es mejor para subir ganzuas o botellas, lo mas rapido. Gracias

[neale]

Botellas con el artesano ya no se pueden hacer, mejor ponte a hacer ganzuas o engranajes.

[Harald]

yo estoy con neale ponlo para acer engranajes anda plis
que yo me quiero subir la artesania pero... no puedo acer ganzuas