[MACRO] Tirar Magia + Medit + Coger Regs

[darksplit]

Pues eso,
es muy simple, alomejor ya rula alguna por aquí, pero yo pongo la mía y seguro que a alguien le sirve.

Sólo te pide de abrir el contenedor de los Regs y elegir el objetivo.
Se pueden editar las variables de cuánto mana consumimos antes de empezar a meditar,
y cuantos Regs se cogen del contenedor cada vez que estemos a 0 de alguno de ellos.

; ------------------------------------------------------
; Macro de Tirar Magia/Medit para UA-Sphere (Sphere 0.56b-Nightly)
; Creado por: darksplit el 08/04/2010
; Ultima edición: N/A
; Modificaciones de: N/A
; ------------------------------------------------------
;
;
; Explicación:
; Se trata de una Macro para Tirar Magia Meditando y reponerse fácilmente
; desde un contenedor. Sólo tienes que abrir el contenedor donde están los regs,
; seleccionar la persona a la que van dirigidos los hechizos y la macro hará el resto.
; Cogerá siempre 100 regs de cada.
; Gastará siempre 20 de maná antes de empezar a meditar
; Para los usuarios más avanzados, dejo las variables a continuación
; por si se quiere poner que gaste más antes de meditar, y por si queréis coger más regs.
;
; ==================================
set %managastado #MAXMANA - 20 ; Este número simboliza el maná gastado máximo antes de meditar
set %numeroregs 100 ; Número de regs que cogerá para reponerse cada vez.
; ==================================

chooseskill mage real
set %skillinimagia #skill
chooseskill medi real
set %skillinimedit #skill
set #sysmsgcol 0000
event sysmessage Iniciando Macro...
event sysmessage
set #targCurs 0

configurar:
if %confp = 1 || %confp = N/A
{
set #sysmsgcol 1264
setuotitle Abre el contenedor donde estan los Regs.
event sysmessage ================
event sysmessage Abre el contenedor de Regs
event sysmessage Presiona la tecla ESC.
event sysmessage ================
set %confp 2
goto TESC
}
if %confp = 2
{
set #sysmsgcol 1264
setuotitle Selecciona tu objetivo
event sysmessage ================
event sysmessage Selecciona tu objetivo
event sysmessage ================
set #sysmsgcol 0000
set #targCurs 1
wait 1s
goto CURSOR
}

CURSOR:
if #TARGCURS = 1
{
goto CURSOR
}
if #TARGCURS = 0
{
set %objetivo #LTARGETID
gosub uotitle
goto loop
}
goto CURSOR


TESC:
onHotKey ESC
{
set %idcaja #LOBJECTID
goto configurar
}
goto TESC

scanjournal 1

loop:
wait 40
repeat
{
gosub check
set #LTARGETID %objetivo
event macro 15 7
wait 8
event macro 22 0
gosub uotitle
}
until #mana <= %managastado
repeat
{
gosub meditar
}
until #mana = #int
goto loop

sub uotitle
wait 10
chooseskill mage real
set %skillmagiaahora #SKILL
chooseskill medi real
set %skillmeditahora #SKILL
finditem KZF C_ , #BACKPACKID
set %cuantogarlic #FINDSTACK
finditem WZF C_ , #BACKPACKID
set %cuantonight #FINDSTACK
setuotitle || Magia | Ini: %skillinimagia | Actual: %skillmagiaahora || Medit | Ini: %skillinimedit | Actual: %skillmeditahora || Regs | Garlic: %cuantogarlic | Night: %cuantonight ||
return

sub meditar
event macro 13 46
if pierdes in #journal
{
gosub meditar ; Meditamos hasta que no perdamos la concentración
}
if trance in #journal
repeat
{
wait 40
event macro 13 46 ; Aseguramos que mientras meditemos no perdamos la concentración. Así que cada 2 segundos meditará.
}
until #mana = #int
return


sub check
finditem WZF C_ , #BACKPACKID
if #FINDCNT = 0
{
gosub abrircaja
wait 5
set %reg WZF
gosub coger
}
finditem KZF C_ , #BACKPACKID
if #FINDCNT = 0
{
gosub abrircaja
set %reg KZF
gosub coger
}
return

sub abrircaja
set #LOBJECTID %idcaja
event macro 17 0
wait 10
return

sub coger
finditem %reg C_ , %idcaja
exevent drag #FINDID %numeroregs
wait 10
exevent dropc #BACKPACKID
wait 10
return

[12younguense]

pero yo no tengo a quien tirarle la magia me la tengo q tirar yo y me dice que no puedo tirarmela a mi mismo le cambiarias el hechizo para que tire a uno mismo