Subir

Resultados 1 al 15 de 15

Tema: Macros de Asuma

  1. #1

    Fecha de ingreso
    January-2009
    Edad
    35
    Mensajes
    42
    Reputacion: 10
    Poder de reputación
    15

    Macros de Asuma

    Una recopilación de las macros que puse en el foro.
    Poco a poco iré agregando más, a medida que las haga.

    1 - Artesanía (Haciendo Botellas Vacías)
    2 - Sastrería (100% Automática)
    3 - Magia. Con Weaken - Des Mani (y Resistencia Mágica para el contrincante).
    4 - Entrenamiento v1. Para entrenar. Se necesita un pilón de agua. Cura al contrincante, limpia vendas, y si se tiene menos de 20 de vida uno de los dos personajes se corre hacia abajo (ambos deben estar usando la misma macro).
    5 - Alquimia.

    1 - Artesanía

    Descripción : Hace botellas vacías.
    Configuración : Se debe corregir, si es necesario, la variable %botella_x por la coordenada X en la que se encuentre la botella.

    Código:
    ; Macro de Artesano by Asuma|Mordor.
    display ok Macro by Asuma/Mordor.
    chooseskill Tink Real
    set %skill_ini #SKILL
    set %herramienta GTL
    set %botella_x 100
    set %limite_botellas 20
    GoSub GetContenedor
    wait 20
    GoSub GetMochila
    wait 1s
    set #SYSMSGCOL 68
    event sysmessage Comenzara la macro...
    wait 1s
    inicio:
    goSub CheckHerramientas
    goSub HacerBotella
    goSub Renovar_Titulo
    goto inicio
    
    
    ; ************************ SUBS ************************
    sub Renovar_Titulo
    set %skill_gain #SKILL - %skill_ini
    FINDITEM WUF C_ , %id_cofre
    set %botellas_cofre #FINDSTACK
    FINDITEM WUF C_ , #BACKPACKID
    set %botellas_mochila #FINDSTACK
    setuotitle | Skill Inicial : %skill_ini | Skill Actual : #skill | P. Ganados : %skill_gain | Botellas Guardadas : %botellas_cofre | Botellas en mochila : %botellas_mochila
    return
    
    sub HacerBotella
    goSub Reponer_Lingotes
    FINDITEM WUF C_ , #BACKPACKID
    IF #FINDSTACK >= %limite_botellas
    {
       set #SYSMSGCOL 68
       event sysmessage Guardando botellas...
       event drag #FINDID
       wait 20
       key Enter
       wait 20
       click %cont_x %cont_y p
       wait 10
       event sysmessage Botellas guardadas.
    }
    FINDITEM %herramienta C_ , #BACKPACKID
    set #LOBJECTID #FINDID
    event macro 17 0
    wait 20
    click 195 80 d
    wait 20
    click %botella_x 80 d
    wait 1s
    return
    
    sub CheckHerramientas
    GoSub Reponer_Lingotes
    FINDITEM %herramienta C_ , #BACKPACKID
    IF #FINDCNT = 0
    {
       event sysmessage No tienes ningun instrumento en la mochila.
       stop
    }
    IF #FINDCNT = 1
    {
       while #FINDCNT < 5
       {
       set #LOBJECTID #FINDID
       event macro 17 0
       wait 20
       click 195 80 d
       wait 20
       click 267 67
       wait 10
       click 267 67
       wait 10
       click 267 67
       wait 10
       click 235 80 d
       FINDITEM %herramienta C_ , #BACKPACKID
       }
    }
    return
       
    sub Reponer_Lingotes
    FINDITEM RMK C_ , #BACKPACKID
    IF #FINDSTACK < 30
    {
       set #SYSMSGCOL 68
       event sysmessage Reponiendo lingotes...
       FINDITEM RMK C_ , %id_cofre
       IF #FINDSTACK < 60
       {
          event sysmessage No hay mas lingotes.
          stop
       }
       event Drag #FINDID
       wait 20
       key 6
       wait 10
       key 0
       wait 10
       key enter
       wait 10
       click %mochila_x %mochila_y p
       event sysmessage Lingotes repuestos.
       wait 1s
    }
    return
       
    sub GetContenedor
    set #SYSMSGCOL 68
    event sysmessage Abra el contenedor donde esten los lingotes, mantenga el cursor en ese lugar y presione ESC.
    get_conte:
    OnHotKey ESC
    {
             set %id_cofre #LOBJECTID
             set %cont_x #CURSORX
             set %cont_y #CURSORY
             return
    }
    goto get_conte:
    return
    
    sub GetMochila
    set #SYSMSGCOL 68
    event sysmessage Coloque el cursor sobre la mochila de la foto de su personaje y presione ESC.
    get_mochi:
    OnHotKey ESC
    {
             set %mochila_x #CURSORX
             set %mochila_y #CURSORY
             return
    }
    goto get_mochi:
    return
    2 - Sastrería

    Descripción : Compra tela, hace lotes, y vende.
    Ventaja : Se necesita muy poco dinero (Al comprar y vender no se pierde nada).
    Desventaja : Para que la macro funcione correctamente sin parar dejar el UO como la ventana activa de windows, es decir, como la ventana principal.
    Probada con EasyUO 1.5 y Funcionando.

    Modo de uso : Se ponen al lado de un vendor, y le dan play. NO es necesario empezar con kits de costura, si no hay, los compra.

    Código:
    ;Macro de Sastrería por Mordor/Asuma.
    ;********************************Configuracion********************************
    set %bandanas_vender 50 ;Cuando llegue a esta cantidad, se venderan.
    ;********************************Macro********************************
    set %rollo ZZF
    set %tela RTI
    set %kit HAG
    set %bandana TDI
    set %menu1_x 192
    set %menu1_y 63
    set %bandana_x 59
    set %bandana_y 66
    chooseskill tail real
    set %skill_ini #skill
    display ok Macro by Asuma/Mordor
    ciclo:
    FINDITEM %rollo C_ , #BACKPACKID
    IF #FINDCNT > 0
    {
    	set #LOBJECTID #FINDID
    	event macro 17 0
    	wait 20
    }
    IF #HITS < 90
    msg guards$
    goSub CompraKit
    goSub CompraTela
    goSub Bandanas
    goSub Renovar_Titulo
    goto ciclo
    
    ;********************************Subs********************************
    
    sub Bandanas
    FINDITEM %bandana C_ , #BACKPACKID
    IF #FINDCNT < %bandanas_vender
    {
    	FINDITEM %kit C_ , #BACKPACKID
    	set #LOBJECTID #FINDID
    	event macro 17
    	target
    	FINDITEM %tela C_ , #BACKPACKID
    	set #LTARGETID #FINDID
    	event macro 22 0
    	wait 17
    	IF #SYSMSG = NO_TIENES_NI_IDEA_DE_COMO_UTILIZAR_ESTO.
    	{
    		wait 20
    		event sysmessage Arreglando bug...
    		goSub Fix
    		wait 20
    		event sysmessage Arreglado
    	}
    	;Ahora selecciono la bandana
    	click %menu1_x %menu1_y d
    	wait 17
    	click %bandana_x %bandana_y d
    	wait 15
    }
    IF #FINDCNT >= %bandanas_vender
    {
    	msg Vendor sell$
    	wait 2s
    	click 329 580
    	wait 2s
    	click 376 151
    	wait 2s
    	click 601 537
    	wait 2s
    }
    return
    
    sub Fix
    set #LOBJECTID #BACKPACKID
    event macro 17 0
    contpos 655 390
    wait 20
    FINDITEM %kit C_ , #BACKPACKID
    event drag #FINDID
    wait 20
    click 838 429 p
    wait 20
    FINDITEM %tela C_ , #BACKPACKID
    event drag #FINDID
    wait 20
    key Enter
    wait 20
    click 707 430 p
    wait 20
    click 824 464 d
    wait 20
    click 710 462 mc
    wait 20
    click 710 462
    wait 2s
    click 100 70 r
    wait 2s
    click 354 252 mc
    return
    
    sub CompraTela
    FINDITEM %tela C_ , #BACKPACKID
    IF #FINDSTACK < 10
    {
    	event sysmessage -----Reponiendo tela...-----
    	msg Vendor buy$
    	wait 2s
    	click 397 258
    	wait 2s
    	click 601 537
    	wait 3s
    	FINDITEM %rollo C_ , #BACKPACKID
    	set #LOBJECTID #FINDID
    	event macro 17 0
    	wait 20
    }	
    return
    
    sub CompraKit
    FINDITEM %kit C_ , #BACKPACKID
    IF #FINDCNT = 1
    {
    	event sysmessage -----Reponiendo kit de costura...-----
    	msg Vendor buy$
    	wait 2s
    	click 398 138
    	wait 2s
    	click 601 537
    	wait 2s
    	goSub Comer
    }
    IF #FINDCNT = 0
    {
    	event sysmessage -----Reponiendo kit de costura...-----
    	msg Vendor buy$
    	wait 2s
    	click 398 138
    	wait 2s
    	click 398 138
    	wait 2s
    	click 601 537
    	wait 2s
    	goSub Comer
    }
    return
    
    sub Comer
    FINDITEM YSD C_ , #BACKPACKID
    set #LOBJECTID #FINDID
    event macro 17 0
    return
    
    sub Renovar_Titulo
    set %skill_gain #skill - %skill_ini
    FINDITEM %tela C_ , #BACKPACKID
    set %c_tela #FINDSTACK
    FINDITEM %bandana C_ , #BACKPACKID
    set %c_bandanas #FINDCNT
    SetUoTitle Sastre | Skill Inicial : %skill_ini | Skill Actual : #skill | Puntos Ganados : %skill_gain | Telas : %c_tela | Bandanas : %c_bandanas
    return
    3 - Magia

    Descripción : Se lanza el hechizo weaken al contrincante. El usuario de la macro irá agarrando de a 200 reagentes (200 de garlic y 200 de nightshade) del cofre indicado.

    Código:
    display ok Macro by Asuma/Mordor.
    set %nightshade WZF
    set %garlic KZF
    set %c_regs 200
    event sysmessage Abra el contenedor de los reagentes y presione ESC.
    get_cont:
    OnHotKey ESC
    {
      set %container_id #LOBJECTID
      wait 20
      event sysmessage Coloque el cursor en la mochila de la foto de su personaje y presione ESC.
      goto get_backpack
    }
    goto get_cont
    get_backpack:
    OnHotKey ESC
    {
      set %backpack_x #CURSORX
      set %backpack_y #CURSORY
      wait 20
      event sysmessage Seleccione a la persona y presione ESC.
      event macro 15 7
      goto get_id
    }
    goto get_backpack
    get_id:
    OnHotKey ESC
    {
      set %pid #LTARGETID
      wait 20
      goto main
    }
    goto get_id
    main:
    if #MANA < 10
    {
     while #mana <> #maxmana
     {
       event macro 13 46
       wait 1s
     }
    }
    gosub Check_Regs
    FINDITEM %nightshade C_ , #BACKPACKID
    set %cantidad_n #FINDSTACK
    FINDITEM %garlic C_ , #BACKPACKID
    set %cantidad_g #FINDSTACK
    setuotitle Nightshade actual : %cantidad_n | Garlic actual : %cantidad_g
    event macro 15 7
    target
    set #LTARGETID %pid
    event macro 22 0
    wait 40
    goto main
    halt
    
    sub Check_Regs
      FINDITEM %nightshade C_ , #BACKPACKID
      if #FINDSTACK = 0
      {
        set #LOBJECTID %container_id
        event macro 17 0
        wait 5s
        FINDITEM %nightshade C_ , %container_id
        if #FINDSTACK < %c_regs
        {
          event sysmessage Se quedo sin reagentes.
          halt
        }
        else
        {
          event sysmessage Reponiendo nightshade...
          event drag #FINDID
          wait 1s
          key 2
          wait 20
          key 0
          wait 20
          key 0
          wait 20
          key enter
          wait 20
          click %backpack_x %backpack_y
          wait 2s
          event sysmessage Reponiendo garlic...
          FINDITEM %garlic C_ , %container_id
          event drag #FINDID
          wait 1s
          key 2
          wait 20
          key 0
          wait 20
          key 0
          wait 20
          key enter
          wait 20
          click %backpack_x %backpack_y
          wait 2s
          event sysmessage Reagentes renovados.
        }
      }
    return
    4 - Entrenamiento v1.

    Descripción : Para curar al personaje con el cual se va a entrenar y limpiar vendas. Además posee un sistema de seguridad. Si se tiene menos de 20 de vida, el personaje se moverá hacia abajo.
    Se necesita : Un contrincante - Vendas - Pilón de Agua - Tener espacio para correr hacia abajo (por lo menos 5 pasos).

    Código:
    ;Macro de Entrenamiento
    display ok Macro by Asuma/Mordor.
    set %vendas ZLF
    set %vendas_sucias AMF
    event sysmessage Seleccione al jugador con el que va a entrenar y presione ESC.
    msg .vendas$
    get_player:
    OnHotKey ESC
    {
      set %player #LTARGETID
      wait 20
      event sysmessage Haga doble click sobre el bidon de agua y presione ESC...
      goto get_bidon
    }
    goto get_player
    get_bidon:
    OnHotKey ESC
    {
      set %bidon #LOBJECTID
      wait 20
      event sysmessage Bidon guardado...
      goto curar
    }
    goto get_bidon
    curar:
    FINDITEM %vendas C_ , #BACKPACKID
    set %va #FINDSTACK
    FINDITEM %vendas_sucias C_ , #BACKPACKID
    set %vs #FINDSTACK
    setuotitle Vendas : %va | Vendas Sucias : %vs | Macro by Asuma/Mordor
    msg .vendas$
    target
    set #LTARGETID %player
    event macro 22 0
    wait 10
    if No_necesita in #SYSMSG
    {
      wait 1s
      goto curar
    }
    wait 6s
    FINDITEM %vendas_sucias C_ , #BACKPACKID
    If #FINDSTACK > 20
    {
      wait 20
      event sysmessage Limpiando vendas...
      set #LOBJECTID #FINDID
      event macro 17 0
      target
      set #LTARGETID %bidon
      event macro 22 0
      event sysmessage Vendas limpias.
      wait 20
    }
    if #HITS < 20
    {
      event sysmessage Peligro de muerte, moviendo al jugador...
      set %next_y #CHARPOSY
      set %next_y %next_y + 10
      move #CHARPOSX %next_y 0 5s
      halt
    }
    goto curar
    5 - Alquimia

    Descripción : Depende lo que elija el usuario (modificando %Veneno por 1 o 0) se crearán pociones de veneneno/veneno menor y se guardarán en un contenedor.
    Se necesita : Un contenedor que tenga Morteros, Nightshade, y Botellas Vacías, otro contenedor para guardar las pociones hechas y una bolsita en la mochila.

    Código:
    ;Macro de Alquimia by Asuma/Mordor.
    set %Veneno 1
    ;Cambiar a 0 si se quiere hacer pociones de veneno comun.
    if %Veneno = 1
    {
      display ok Va a macrear con pociones de veneno menor gracias a Asuma/Mordor.
    }
    else
    {
      display ok Va a macrear con pociones de veneno gracias a Asuma/Mordor.
    }
    set %frasco WUF
    set %mortero RQF
    set %nightshade WZF
    event sysmessage 1) Haga doble click en el contenedor donde esten las pociones, los reagentes y morteros.
    set #SYSMSGCOL 68
    event sysmessage Al tener esto listo, presionar ESC (Escape).
    set #SYSMSGCOL 0
    GetContainer:
    OnHotKey ESC
    {
      set %container #LOBJECTID
      wait 20
      event sysmessage 2) Mantenga el cursor en el contenedor donde dejara sus pociones de veneno menor.
      set #SYSMSGCOL 68
      event sysmessage Al tener esto listo, presionar ESC (Escape).
      set #SYSMSGCOL 0
      goto next_container
    }
    goto GetContainer
    next_container:
    OnHotKey ESC
    {
      set %pot_cont_x #CURSORX
      set %pot_cont_y #CURSORY
      wait 20
      event sysmessage 3) Mantenga el cursor en la mochila de la foto de su personaje.
      set #SYSMSGCOL 68
      event sysmessage Al tener esto listo, presionar ESC (Escape).
      set #SYSMSGCOL 0
      goto get_backpack
    }
    goto next_container
    get_backpack:
    OnHotKey ESC
    {
      set %backpack_x #CURSORX
      set %backpack_y #CURSORY
      wait 20
      event sysmessage 4) Haga doble click en la bolsa ubicada en su mochila y mantenga la posicion del cursor.
      set #SYSMSGCOL 68
      event sysmessage Al tener esto listo, presionar ESC (Escape).
      set #SYSMSGCOL 0
      goto get_bolsita
    }
    goto get_backpack
    get_bolsita:
    OnHotKey ESC
    {
      set %bolsita_x #CURSORX
      set %bolsita_y #CURSORY
      set %bolsita #LOBJECTID
      wait 2s
      event sysmessage Datos guardados.
      wait 20
      goto main
    }
    goto get_bolsita
    main:
    key ESC
    gosub Renovar_Titulo
    gosub CheckRegs
    gosub CheckMortero
    gosub CheckFrasco
    FINDITEM %mortero C_ , #BACKPACKID
    if #FINDCNT = 0
    {
      goto main
    }
    set #LOBJECTID #FINDID
    event macro 17 0
    target
    FINDITEM %nightshade C_ , %bolsita
    if #FINDSTACK = 0
    {
      goto main
    }
    set #LTARGETID #FINDID
    event macro 22 0
    wait 1s
    if %Veneno = 1
    {
    click 58 67 d
    }
    else
    {
    click 102 67 d
    }
    wait 12s
    FINDITEM WUF C_ , #BACKPACKID
    wait 1s
    if #FINDSTACK > 9
    {
      event drag #FINDID
      wait 20
      key enter
      wait 20
      click %pot_cont_x %pot_cont_y
      wait 20
      event sysmessage Pociones guardadas.
    }
    goto main
    
    sub CheckFrasco
    FINDITEM %frasco C_ , %bolsita
    if #FINDSTACK = 0
    {
      FINDITEM %frasco C_ , %container
      if #FINDSTACK = 0
      {
        event sysmessage Se quedo sin frascos vacios.
        halt
      }
      else
      [
        event drag #FINDID
        wait 20
        key 1
        wait 20
        key enter
        wait 10
        click %bolsita_x %bolsita_y
        wait 20
        event sysmessage Se tomo un frasco vacio.
      }
    }
    return
    
    sub CheckMortero
    FINDITEM %mortero C_ , #BACKPACKID
    if #FINDCNT = 0
    {
      FINDITEM %mortero C_ , %container
      if #FINDCNT = 0
      {
        event sysmessage Se quedo sin morteros.
        halt
      }
      else
      {
        event drag #FINDID
        wait 10
        click %backpack_x %backpack_y
        wait 20
        event sysmessage Se repuso un mortero.
      }
    }
    return
    
    
    sub CheckRegs
    FINDITEM %nightshade C_ , %bolsita
    if #FINDSTACK < 2
    {
      FINDITEM %nightshade C_ , %container
      if #FINDSTACK < 50
      {
        event sysmessage Debe tener minimo 50 reagentes nightshade.
        halt
      }
      else
      {
        event drag #FINDID
        wait 20
        key 5
        wait 10
        key 0
        wait 10
        key enter
        wait 10
        click %bolsita_x %bolsita_y
        wait 20
        event sysmessage Nightshade repuesto.
      }
    }
    return
    
    sub Renovar_Titulo
    FINDITEM %frasco C_ , #BACKPACKID
    setuotitle Pociones en mochila : #FINDSTACK | Macro by Asuma/Mordor.
    return
    Eso es todo por ahora.
    NOTA : Para las macros que requieren doble click, como por ejemplo Artesanía, no utilizar Razor.
    Última edición por Asuma; 21-Jul-2009 a las 05:54

  2. #2

    Fecha de ingreso
    January-2009
    Edad
    35
    Mensajes
    42
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    Espacio para futuras macros.

  3. #3
    Avatar de Portgas D Ace
    Fecha de ingreso
    July-2009
    Mensajes
    172
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    Gracias por la de magia, me hacia falta ^^
    ¡¡¡VIVAN LAS BORSAS DE KIKOS!!!

  4. #4

    Fecha de ingreso
    January-2009
    Edad
    35
    Mensajes
    42
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    Me alegro que sirva.
    Un saludo.

  5. #5
    Avatar de yeladies
    Fecha de ingreso
    September-2007
    Ubicación
    León
    Edad
    40
    Mensajes
    228
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    La de sastre me viene de perlas!

    Muchas gracias.

  6. #6

    Fecha de ingreso
    January-2009
    Edad
    35
    Mensajes
    42
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    Me alegro. Un saludo.
    Última edición por Asuma; 21-Jul-2009 a las 05:55

  7. #7

    Fecha de ingreso
    January-2009
    Edad
    35
    Mensajes
    42
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    Actualizado.
    Se agregó macro de Alquimia.

    Espero sirva.

  8. #8
    Avatar de scaleote
    Fecha de ingreso
    October-2008
    Edad
    42
    Mensajes
    631
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    1º Muchas gracias por tan buenas macros y 2º me podrias decir como ha de estar el pilon en la macro de curar, en la mochila o bloqueado es q no me limpia las vendas de ninguna de las maneras saludos.

  9. #9

    Fecha de ingreso
    February-2010
    Edad
    37
    Mensajes
    484
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    está bien esto de recopilar, felicidades, jejeje
    y bien pensado lo de correr, yo confio en mi macro de luchar y no le pongo correr, pero ya lo hare el dia que muera jajajaja

    porcierto, lo de sastre, porqué ocurre eso?
    porqué no has puesto que sea "don't move cursor" ?

  10. #10
    Avatar de scaleote
    Fecha de ingreso
    October-2008
    Edad
    42
    Mensajes
    631
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    Bueno ya descubri que el pilon, va en la mochila y no me limpiaba por que tenia un objeto medio tapandolo espero que le sirva a alguien. Saludos

  11. #11
    Avatar de xmurdocx
    Fecha de ingreso
    February-2008
    Facción
    Neutral
    Nacimiento
    Haven
    Edad
    41
    Mensajes
    1.060
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    loko muchas gracias x las macros van de maravilla

  12. #12

    Fecha de ingreso
    August-2011
    Edad
    39
    Mensajes
    32
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    Buenas, lo primero felicitarte por hacer unas macros tan buenas, todas me han funcionado a la perfeccion menos la de sastreria,el problema es que me pongo al lado del vendor, compra los kits, la tela y usa el kit de curticion pero me salen los menus y empiezan a moverse y se me va llenando la pantalla de menus pero no hace ninguna bandana de esas... alguna ayuda?

    Muchas gracias!

  13. #13
    Avatar de Aloisia
    Fecha de ingreso
    January-2010
    Mensajes
    813
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    No uses razor con macros de easyuo que manejen menús, ya que los mueve del sitio.

    Si usas macros de Easyuo que crafteen objetos, hazlo usando el cliente sin Razor.

  14. #14

    Fecha de ingreso
    January-2009
    Edad
    39
    Mensajes
    171
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    A mí me funcionaron todas.

    En la de sastre, haz doble click en el kit de costurero y luego selecciona con el target la tela, para que pille el lastarget, desde ese momento, tendría que ir bien, al menos yo lo hice así y gm

  15. #15
    Avatar de Cabalier
    Fecha de ingreso
    March-2011
    Mensajes
    962
    Reputacion: 14
    Poder de reputación
    15

    Respuesta: Macros de Asuma

    estoy intentando subir artesania y la tengo a 30 la skill entonces lo k hace la macro es:
    abre el menu de los objetos le da a herramienta y me sale mortero tigeras y kit de costura el caso es k le da a la derecha dos veces y cancela y asi sin hacer nada

Temas similares

  1. Macros.
    Por Saxo VTS en el foro Macros
    Respuestas: 3
    Último mensaje: 06-Aug-2008, 02:11
  2. Macros de uo
    Por CopaDeBastos en el foro Macros
    Respuestas: 5
    Último mensaje: 15-Feb-2008, 00:27

Permisos de publicación

  • No puedes crear nuevos temas
  • No puedes responder temas
  • No puedes subir archivos adjuntos
  • No puedes editar tus mensajes
  •  
YoutubeFbChat IRCTwit