Subir

Resultados 1 al 2 de 2

Tema: [Aporte] Macro de escriba

  1. #1

    Fecha de ingreso
    April-2011
    Mensajes
    120
    Reputacion: 11
    Poder de reputación
    13

    [Aporte] Macro de escriba

    Buenas a todos,

    Os traigo el primer macro que he hecho más en serio...
    Me propuse hacerlo al no encontrar ninguno que me funcionara al 100% en el foro. No presumo que este lo haga, pero por ahora llevo 24h ininterrumpidas de macreo sin que de problemas...

    He de decir que he aprovechado trozos de código de otros macros, como la parte de meditar del macro de magia hecho por Darksplit en el 2010 o el mismo de inscripción de Overking (la parte de los 3 cofres me la he copiado de ti :P)

    Necesitáis 3 cofres, uno con las plumas, otro con los regs (ceniza sulfurosa) y los lotes de pergaminos y un tercero para dejar los pergaminos de flecha mágica.

    (si lo váis probando y os da algún error decidmelo y lo intentare solucionar cuanto antes)

    Agradecimientos: A Overking y sus macros fáciles de entender, que me han ayudado a adentrarme en easyUO ^^

    Código:
    ;==================================================
    ;INSCRIPTION BY JAVIERCV
    ;==================================================
    set #SYSMSGCOL 10
    event sysmessage Macro de inscripcion by JavierCV
    
    ;CONFIGURACIÓN=====================================
    set %cofre1 BCCCUOD ;cofre con plumas
    set %cofre2 JUMDGOD ;cofre con regs y lotes de pergaminos
    set %cofre3 NNIDGOD ;cofre donde dejar los pergaminos
    ;==================================================
    set %regs SZF       ;ceniza sulfurosa
    set %pergamino MMF  ;ID pergamino en blanco
    set %lote MMF       ;ID lote de pergaminos en blanco
    set %pluma CXF_PBG  ;ID pluma
    set %pergaminoFM CYL ;ID pergamino de flecha mágica
    set %comida YSD_QQD_FUD_HND ;comida
    ;==================================================
    set %numRegs 100    ;número de regs a coger
    set %numLotes 5     ;número de lotes a coger
    ;==================================================
    set %lotesgastados 0    ;contador de lotes gastados
    set %plumasgastados 0   ;contador de plumas gastadas
    set %regsgastados 0     ;contador de regents gastados
    set %fmcreados 0        ;contador de pergaminos creados
    ;==================================================
    
    
    ;UOTITLE INICIAL===================================
    chooseskill Insc real
    set %skillini #skill
    ;==================================================
    
    
    ;HILO PRINCIPAL DEL MACRO==========================
    loop:
         wait 40
         gosub uotitle
         gosub check
         if #MANA <= 5
         {
            gosub meditar
            gosub comer
         }
         if #WEIGHT >= 200
         {
            gosub dejarpergas
         }
         if #WEIGHT >= 350
         {
            gosub seguridad
         }
         gosub hacerpergas
         wait 40
    goto loop
    ;==================================================
    
    
    ;SUB HACER PERGAMINOS==============================
    sub hacerpergas
        finditem %pluma C_ , #BACKPACKID
        set #LOBJECTID #FINDID
        event macro 17 0
        wait 10
        finditem %pergamino c_ , #BACKPACKID
        set #LOBJECTID #FINDID
        event macro 17 0
        click 65 130 ;primer circulo
        wait 3s
        for %x 1 9
        {
            click 274 190 ;flecha mágica
            wait 5s
            set %fmcreados %fmcreados + 1
        }
    return
    ;==================================================
    
    
    ;SUB DEJAR PERGAMINOS==============================
    sub dejarpergas
        findItem %pergaminoFM C_ , #BACKPACKID
        if #findcnt > 0
        {
           exevent drag #FINDID #FINDSTACK
           wait 10
           Exevent Dropc %cofre3
           wait 10
           gosub dejarpergas
        }
    return
    ;==================================================
    
    
    ;SUB MEDITAR=======================================
    sub meditar
    repeat
    {
        event macro 13 46
        if pierdes in #journal
        {
           gosub meditar ; Meditamos hasta que no perdamos la concentración
        }
        if trance in #journal
           repeat
           {
               wait 40
               event macro 13 46 ; Aseguramos que mientras meditemos no perdamos la concentración. Así que cada 2 segundos meditará.
           }
           until #mana = #int
        }
    }
    until #mana = #int
    return
    ;==================================================
    
    
    ;SUB CHECK=========================================
    sub check
        ;¿TIENE REGS?
        finditem %regs C_ , #BACKPACKID
        if #FINDSTACK < 5
        {
           set #LOBJECTID %cofre2
           event macro 17 0
           finditem %regs C_ , %cofre2
           exevent drag #FINDID %numRegs
           wait 10
           exevent dropc #BACKPACKID
           wait 10
           set %regsgastados %regsgastados + %numRegs
        }
        ;¿TIENE LOTES?
        finditem %lote C_ , #BACKPACKID
        if #FINDSTACK = 0
        {
           set #LOBJECTID %cofre2
           event macro 17 0
           finditem %lote C_ , %cofre2
           exevent drag #FINDID %numLotes
           wait 10
           exevent dropc #BACKPACKID
           wait 10
           for %i 1 7
           {
              finditem %lote C_ , #BACKPACKID
              set #LOBJECTID #FINDID
              event macro 17 0
              wait 10
           }
           set %lotesgastados %lotesgastados + %numLotes
        }
        ;¿TIENE PLUMAS?
        finditem %pluma C_ , #BACKPACKID
        if #FINDSTACK = 0
        {
           set #LOBJECTID %cofre1
           event macro 17 0
           finditem %pluma C_ , %cofre1
           exevent drag #FINDID
           wait 10
           exevent dropc #BACKPACKID
           wait 10
           event macro 17 0
           wait 10
           set %plumasgastados %plumasgastados + 1
        }
    return
    ;==================================================
    
    
    ;SUB COMER=========================================
    sub comer
        findItem %comida C_ , #BACKPACKID
        set #LOBJECTID #FINDID
        wait 10
        event macro 17
    return
    ;==================================================
    
    
    ;SEGURIDAD=========================================
    sub seguridad
        ;si por algún motivo el peso llegara a ser excesivo, mueve todos los pergaminos de la mochila al cofre de las plumas
        findItem %pergamino C_ , #BACKPACKID
        if #findcnt > 0
        {
           exevent drag #FINDID #FINDSTACK
           wait 10
           Exevent Dropc %cofre1
           wait 10
        }
    return
    ;==================================================
    
    
    ;UOTITLE ==========================================
    sub uotitle
        chooseskill Insc real
        set %skillact #skill
        setuotitle Inscripción [ Ini: %skillini | Actual: %skillact ] || [ Lotes: %lotesgastados | Regs: %regsgastados | Plumas: %plumasgastados | FM creados: %fmcreados ]
    return
    ;==================================================

  2. #2
    Suspendido
    Fecha de ingreso
    September-2016
    Ubicación
    Mallorca
    Clan
    GoD
    Facción
    Corsario
    Nacimiento
    Haven
    Mensajes
    706
    Reputacion: 130
    Poder de reputación
    0

    Re: [Aporte] Macro de escriba

    Buena macro
    Me alegro de que mi trabajo te sirviera ^^

Temas similares

  1. Aporte mis Script.
    Por Envy en el foro Scripts
    Respuestas: 7
    Último mensaje: 16-Sep-2011, 21:25
  2. macro escriba
    Por caniman en el foro Macros
    Respuestas: 0
    Último mensaje: 01-Sep-2011, 05:30
  3. Macro de Escriba
    Por Estrella en el foro Macros
    Respuestas: 1
    Último mensaje: 29-Sep-2008, 02:43
  4. Macro de Escriba
    Por NeTBuSII en el foro Macros
    Respuestas: 3
    Último mensaje: 23-Jun-2008, 15:52
  5. Macro Escriba
    Por Yeni en el foro Macros
    Respuestas: 0
    Último mensaje: 13-Nov-2007, 01:26

Permisos de publicación

  • No puedes crear nuevos temas
  • No puedes responder temas
  • No puedes subir archivos adjuntos
  • No puedes editar tus mensajes
  •  
YoutubeFbChat IRCTwit