Subir

Resultados 1 al 3 de 3

Tema: 2 pajaros de un 1 tiro

  1. #1
    Staff Ultima Alianza Avatar de Sir Drunk
    Fecha de ingreso
    December-2006
    Ubicación
    La isla
    Clan
    Hijos del Viento
    Facción
    Neutral
    Nacimiento
    Otros - Extranjero
    Mensajes
    6.263
    Reputacion: 137
    Poder de reputación
    15

    2 pajaros de un 1 tiro

    Alguien pregunto hace par de días como es la quest del tío que esta en el cementerio de brit. Y justo ayer alguien me pidió el script de una quest para ver como se hacen, por que quiere hacer unas scripts.


    Así que, matemos 2 pájaros de un tiro.


    Código:
    ///////////////////////////////////////////////////////////////////////////////////////////////////////////
    ///////////////////////////////////////////////////////////////////////////////////////////////////////////
    // Quest de un ladron que tiene en la ciudad a su mujer embarazada. El ladron queire ir a verla pero    ///
    // tiene karma negativo. Y no puede entrar a la ciudad. Pide a la gente un anillo del bien que le suba  ///
    // el karma y pueda entrar a la ciudad sin las molestias de la guardia.    Da 5000 gps.             ///
    //                                                        ///
    // 500 segs despues de recibir el anillo el ladron lo perdera y volvera en invis al lugar de partida    ///
    ///////////////////////////////////////////////////////////////////////////////////////////////////////////
    ///////////////////////////////////////////////////////////////////////////////////////////////////////////
    // 1 / 6 / 07 by Drunk
    
    
    
    ////////////////////////////////////////////////////////////////////////////////////////////////////////
    //// Memoria que hace retornar al npc a su lugar de origen a los 500 segundos de completarse la m   ////
    //// ITEM MEMORIA -- se ekipa en el npc.Tambien le bajar el karma anulando el efecto del anillo     ////
    ////////////////////////////////////////////////////////////////////////////////////////////////////////
    
    [ITEMDEF i_memoria_cambia_homekarma] 
    ID=i_memory
    TYPE=t_eq_script
    NAME=[MEMORIA HOME NUEVA]
    
    ON=@CREATE
    ATTR=attr_decay|attr_invis
    TIMER=500
    TAG.CONTADOR=0
    
    
    ON=@TIMER
    IF (<TAG0.CONTADOR> == 0)
        LINK.HOME=<LINK.TAG.HOME>
        LINK.KARMA=-2000
        TAG.CONTADOR= 1
        LINK.FLAGS 02000
        TIMER=500
        LINK.SAY Oh! no dios mio! se me ha caido el anillo! 
    ELSE 
        LINK.FLAGS 00
        LINK.SAY Algun dia tendre suerte? Todo lo que me pasa es por el dolor que he causado!
        REMOVE
    ENDIF
    RETURN 1 
    
    
    
    ///////////////////////////////////////////////////////////////////////////////////////////////////////
    ////  Este es quien te otorga la mision y es la parte visible de la quest.                         ////
    ////  NPC / CHAR -- Funciona por el speeck -- Recoge item i_anillo_karma y da 5000gp               ////
    ///////////////////////////////////////////////////////////////////////////////////////////////////////
    
    [CHARDEF c_h_ladron_karma] 
    NAME=#NAMES_HUMANMALE
    ID=c_man
    ARMOR=15
    
    
    CATEGORY=Quest 
    SUBSECTION=Quest Ladron
    DESCRIPTION=Ladron sin karma
    
    TSPEECH=qa_quest_pide_anillo
    
    ON=@NPCSEENEWPLAYER                                            
    IF (rand(3)==1)
        Say Hola amigo <SRC.NAME>, tienes un momento?
        IF (rand(2)==1)
            EMOTE maldice su suerte.
        ENDIF
    ENDIF
    
    ON=@CREATE
    TITLE=Ladron apenado
    //IF (rand(2)==1)
    //    body=c_woman
    //    TITLE=Hija de Nobles
    //    NAME=#NAMES_HUMANFEMALE
    //    // Al tener ID c_MAN se ve como un hombre... buscar algun parche para arreglarlo 
    //ENDIF
    STR={70 150}
    DEX={50 180}
    INT={50 170}
    
    //allskills=765
    //Hiding=888
    
    KARMA=-2000
    TAG.CONTADOR=0
    TAG.HOME_ALT=1448,1546,30    
    // se mueve a este home cuando alguien le cumple la mision. Simula entrar a la ciudad
    
    SPEECHCOLOR=45
    COLOR=colors_skin
    NPC=brain_human
    
    ITEMNEWBIE=i_hair_short
    COLOR=colors_neutral
    //ITEMNEWBIE=i_cape
    //COLOR=colors_neutral
    ITEMNEWBIE=i_shirt_plain
    COLOR=colors_all
    ITEMNEWBIE=i_pants_long
    COLOR=colors_all
    ITEMNEWBIE=i_sandals
    COLOR=colors_all
    ITEMNEWBIE=i_lantern
    
    ON=@CLICK
    IF (<TAG0.CONTADOR> == 0)
        TAG.HOME=<HOME> // Truco para ke guarde su HOME. al hacerlo en el create se ponia -1-1
    ENDIF
    TAG.CONTADOR= 1
    IF (rand(3)==1)
        SAY Pssss Pssss ven aqui... solo sera un segundo... 
    ENDIF
    
    
    ON=@RECEIVEITEM
    IF ((<SRC.FINDLAYER(31).BASEID>==i_anillo_karma) && (<SRC.FINDID.i_memoria_mision_recompensa.timer> > 3600))
        SAY Ah! veo que has cumplido tu mision!
        SRC.NEWITEM i_gold
        SRC.ACT.AMOUNT 5000
        SRC.ACT.BOUNCE
        SRC.FINDLAYER(31).REMOVE
        SRC.FINDID.i_memoria_mision_recompensa.timer=3600
        KARMA=2000
        HOME=<TAG.HOME_ALT>
        NEWITEM i_memoria_cambia_homekarma
        ACT.CONT <UID>
        ACT.LINK <UID>
        SAY Gracias! ahora podre ver a mi familia! 
    ELSE
        SAY Que demonios es esto? Buaj! que te crees que soy la basura? Desaparece de mi vista.
    ENDIF
    
    
    
    ////////////////////////////////////////////////////////////////////////////////////////////////////////
    /////  Speech principal valido para casi cualquier npc de recompensas //////////////////////////////////
    ///// SPEECH Ojo si se usa para otro npc se tiene que copiar y cambiar el valor del rand del "FACIL" ///
    ////////////////////////////////////////////////////////////////////////////////////////////////////////
    
    [SPEECH qa_quest_pide_anillo]
    
    ON=*buen* 
        SAY Bueno seria poder ir a casa...
        TAG.CONFIRMACION=0
        
    ON=*hola* 
    ON=*Salu* 
    ON=*nas*
        SAY Seguro que tu me puedes ayudar! 
        TAG.CONFIRMACION=0
    
    ON=*ayuda*
        Dorand 4
            SAY Quiero ir a la ciudad a visitar a mi esposa embarazada!  
            SAY Cada vez que intento entrar la guardia se echa sobre mi y no puedo ir a ver a mi mujer!
            SAY Quiero el perdon, quiero ver a mi mujer que va a dar a luz! Podrias ayudarme?
            SAY Pagaria por poder ver a mi familia! Lo necesito! Daria todo lo que tengo.
        enddo
        
    ON=*como estas*
    ON=*como te encuentras*
        SAY Muy triste... no me quedan lagrimas sino las verias caer por mi rostro!
        emote agacha la cabeza
    
    ON=*podria*    
    ON=*como*
        SAY Si consigues alguna forma de que mi karma suba te dare una recompensa!
        
    ON=*cual*
    ON=*anillo*
        SAY He oido que existe un anillo que sube el karma. Quizas con el... 
        SAY Que te pareceria toda mi bolsa de oro por el anillo?
        tag.confirmacion= 1
    
    ON=*cuanto*
    ON=*bolsa*
    ON=*recompensa*
    ON=*oro*
        SAY Te dare 5000 monedas de oro. Que te parece? 
        
    ON=*karma*
        SAY Tengo un mal Karma por todo lo que he robado y el dolor que he causado. 
        
    ON=*mujer*
        SAY Mi mujer esta dentro de la ciudad, esta de parto y quiero ir a verla! Necesito un anillo del bien para despistar la guardia
        tag.confirmacion= 1
        
    ON=*guardia*
        SAY Nada mas verme la guardia se lanza sobre mi! Me reconocen! Si pudiera camuflarme!
        
    ON=*caza*
        SAY Si, he oido que los cazadores de brujas tienen un anillo que me vendria bien.
        
    ON=*brujas*
        SAY Lo malo es que no se donde estan esos Cazadores de Brujas.
        
    ON=*cuando*
        SAY Cuanto antes mejor! El tiempo apremia.
    
    ON=*bebe*
        SAY Me muero de ganas por estar con mi mujer y el recien nacido.
    
    ON=*ciudad*
        SAY Si, mi mujer esta en casa de su padre. En Britain. 
        
    ON=*tiempo*
        SAY Mi hijo vera la luz en cualquier momento, no creo que tengas mas de 24 horas.
        SRC.SYSMESSAGE @0 Tienes 24 horas desde que aceptes la mision. //Agregar tiempo restante en el futuro.
        
    ON=*dificil*
        SAY Que te parece dificil? uhm... que pena... no conoces a alguien que me pueda ayudar? 
        SAY Si lo conoces traelo por favor! 
        TAG.CONFIRMACION=0
        BYE
        
    ON=*facil*
        SAY  Bien! gracias! 
    
    ON=*bien*
        Dorand 2
            Say Veo que te gusta la idea, aceptas la mision?
            SAY Si, el anillo del bien, es lo que necesito! y pagaria toda mi bolsa por el!
        enddo
        tag.confirmacion= 1
    ON=*acepto*
    ON=*vale*
        IF (<SRC.FINDID.i_memoria_mision_recompensa>)
            SRC.SYSMESSAGE @0 Aun no puedo asignarte otra mision, te falta <SRC.FINDID.i_memoria_mision_recompensa.timer> segundos! 
        ELSE
            IF (<TAG0.CONFIRMACION>)
                SRC.SYSMESSAGE @0 Tu mision sera traerme un anillo del bien por 5000 monedas de oro.!
                TAG.CONFIRMACION=0
                SRC.NEWITEM i_memoria_mision_recompensa
                    SRC.ACT.CONT <SRC.UID>
                     SRC.ACT.LINK <SRC.UID>
                     SRC.ACT.TIMER 90000
                     SAY Me gusta oir eso. Se te ve que eres una persona valiente!
                     SAY En caso de que no des con un anillo del bien puedes abandonar mision que yo lo comprendere.
            ELSE
                SAY COMO? me tomas el pelo? si aun no te he dicho que tienes que matar para mi! 
                SAY Que tengas un buen dia.
            ENDIF
            TAG.CONFIRMACION=0
            BYE
            
        ENDIF
    ON=*mal*
    ON=*adios*
    ON=*bye*
    ON=*bb*
        TAG.CONFIRMACION=0
        SAY Que tengas un buen dia por que yo no lo tendre.
         BYE
    
    ON=*abandonar mision* 
        SAY Me duele mucho que digas eso...
        // No kita nada. si aceptas la mision tienes 24 h sin otra mision a menos ke lo completes entonces tienes solo 1 hora de espera.
    
    [EOF]
    Última edición por Sir Drunk; 12-Nov-2010 a las 03:02
    Sir Drunk [Hijos del Viento]
    Email Corporativo: [email protected]
    Email Gmail: [email protected]

  2. #2

    Fecha de ingreso
    June-2009
    Edad
    40
    Mensajes
    40
    Reputacion: 10
    Poder de reputación
    15

    Respuesta: 2 pajaros de un 1 tiro

    Se agradece muy interesante.

  3. #3

    Fecha de ingreso
    June-2010
    Edad
    36
    Mensajes
    24
    Reputacion: 10
    Poder de reputación
    0

    Respuesta: 2 pajaros de un 1 tiro

    jaja

    La verdad es que a ese tío le apasiona el peligro del cemen :P

    Gran aporte. Vienen genial para tener ejemplos.

Temas similares

  1. masi, me tiro!
    Por Callipso en el foro Wazaaa
    Respuestas: 8
    Último mensaje: 27-Mar-2010, 20:00
  2. pajaros azules en el puente de vesper?
    Por papafritA- en el foro Dudas y Preguntas
    Respuestas: 5
    Último mensaje: 23-Oct-2009, 15:50
  3. Tiro magias!!
    Por unk en el foro Dudas y Preguntas
    Respuestas: 0
    Último mensaje: 14-Jul-2009, 09:27
  4. Tiro magias!
    Por Asuma en el foro Macros
    Respuestas: 0
    Último mensaje: 12-Jul-2009, 05:48
  5. Tiro magia 24 h
    Por RitaBarbera en el foro Macros
    Respuestas: 1
    Último mensaje: 02-Jun-2007, 22:18

Permisos de publicación

  • No puedes crear nuevos temas
  • No puedes responder temas
  • No puedes subir archivos adjuntos
  • No puedes editar tus mensajes
  •  
YoutubeFbChat IRCTwit