ayuda con macros

[Pikarumon]

Buenas a todos, quiero empezar diciendo que no tengo nidea del easyuo, yo como mucho era de autopìlot jeje, me gustaria una macro sencilla de configurar(hasta ahora no pude poner en marcha ninguna del foro O.o) que subiera la habilidad de mineria, tipo que mine solo o algo parecido, si se complementa con alguna de herreria mejor pero tampoco me gusta exigir, ayudadme en lo que podais o en lo que querais, toda ayuda es bienvenida . gracias

[Olwe]

Subir minería tienes dos opciones una separando ores 1 por uno y fundiendolo y la otra minando hay varias macros disponible busca bien ¡¡¡ para ambos casos

[Pikarumon]

ya tio el corage es que hay muchas y no valgo para ninguna jajaj deberia de centrarme en una y preguntar las dudas sobre esa, gracias por la respuesta

[f.nandoco]

hola muy buenas Pikarumon, te copio la macro que tengo yo para subir mineria. Esta la saque del foro y la repare, hace poco que la use y funciona perfectamente o eso creo jejjeej.

Bueno lo que hace la macro, es te separa los ores, de uno en uno, y te los va dejando en tu mochila. Lo unico que tienes que hacer es darle al play y seguir las instrucciones que te dice. Bueno ya me diras que tal te va compi!!!



;--------------------------
set %sep 50
:--------------------------
initevents
set %confp 1
chooseskill mini
set %skillini #skill

configurar:
if %confp = 1
{
set #SYSMSGCOL 1264
Event sysmessage Abre el cofre en el que tienes los ores a separar y manten el cursor en el.
event sysmessage Y presiona la tecla ESC
setuotitle Abre el contenedor que contiene los ores y luego manten el cursor en el y presiona ESC
set %conf 1
set %confp 2
goto TESC
}
if %confp = 2
{
set #SYSMSGCOL 1264
setuotitle Pon el cursor donde quieras llevar el objeto a separar de tu mochila y presiona ESC
event sysmessage Pon el cursor donde desees dejar el objeto a separar
event sysmessage Y presiona la tecla ESC
set %conf 2
goto TESC
}

TESC:
onHotKey ESC
{
if %conf = 1
{
set %cofre #LOBJECTID
goto configurar
}
if %conf = 2
{
set %dejarx #CURSORX
set %dejary #CURSORY
set %tot 0
set %vez 0
set %fin 0
goto separar
}
}
goto TESC


separar:
event sysmessage ================
event sysmessage separando
event sysmessage ores
event sysmessage ================
gosub abrircofre
set %skillinc #SKILL - %skillini
for %vecesS 1 %sep
{
finditem TVJ c_ , %cofre
if #FINDSTACK = 0
{
finditem GWJ C_ , %cofre
if #FINDSTACK = 0
{
finditem EWJ C_ , %cofre
if #FINDSTACK = 0
{
finditem DWJ C_ , %cofre
if #FINDSTACK = 0
{
set %fin 1
}
}
}
}

event drag #FINDID
wait 5
msg 1 $
click %dejarx %dejary p
wait 1s
setuotitle Accion: Separando | Cantidad: ( %vecesS / %sep ) | Veces: %vez | Guardado: %tot | S. Inicial: %skillini | S. Actual: #SKILL | S. Inc: %skillinc
}

fundir:
event sysmessage ================
event sysmessage fundiendo
event sysmessage ores
event sysmessage ================
set #SYSMSGCOL 0000
finditem TVJ C_ , #BACKPACKID
if #FINDSTACK > 0
{
set #LOBJECTID #FINDID
event macro 17
set %vecesF %vecesF + 1
setuotitle Accion: Fundiendo | Cantidad: ( %vecesF / %sep ) | Veces: %vez | Guardado: %tot | S. Inicial: %skillini | S. Actual: #SKILL | S. Inc: %skillinc
wait 10
goto fundir
}
if %fin = 1
{
set %fin 2
}
set %vecesF 0

guardar:
event sysmessage ================
event sysmessage guardando
event sysmessage mineral
event sysmessage ================
set #SYSMSGCOL 0000
setuotitle Accion: Guardando | Veces: %vez | Guardado: %tot | Inicial: %skillini | Actual: #SKILL | Inc: %skillinc
finditem RMK C_ , #BACKPACKID
if #FINDSTACK = 0
{
finditem NMK C_ , #BACKPACKID
if #FINDSTACK = 0
{
finditem XMK C_ , #BACKPACKID
if #FINDSTACK = 0
{
finditem TMK C_ , #BACKPACKID
if #FINDSTACK = 0
{
goto separar
}
}
}
}

exevent drag #FINDID #FINDSTACK
wait 7
exevent dropc %cofre
wait 10
set %tot %tot + #FINDSTACK
finditem RMK C_ , #BACKPACKID
if #FINDSTACK = 0
{
finditem NMK C_ , #BACKPACKID
if #FINDSTACK = 0
{
finditem XMK C_ , #BACKPACKID
if #FINDSTACK = 0
{
finditem TMK C_ , #BACKPACKID
if #FINDSTACK = 0
{
if %fin = 2
{
gosub finalizar
}
}
}
}
}
if #FINDSTACK > 0
{
goto guardar
}
set %vez %vez + 1
goto separar

sub finalizar
{
display OK Se ha finalizado la macro!$No se ha encontrado más mineral que fundir.
halt
}

sub abrircofre
set #LOBJECTID %cofre
event macro 17 0
wait 30
return.

[Pikarumon]

Muchas gracias, ahora mismo estoy con una macro que meditaba pìcaba solo iba a casa y lo guardaba por medio de runas y volvia a la mina, como a mi no me lo hacia empece a borrar cosas en la macro y ahora solamente mina como un loco sin parar( a veces con los save del juego se queda parao pero stop & play y vuelve a funcionar ) la que me has pasao creo que el problema es que el mineral lo tengo en la mochila no en un cofre, pero bueno ire llevando mineral al cofre y cuando tenga mucho lo fundo, gracias compañero

[Pikarumon]

Nandoco compañero la macro se queda pillada al principio, en vez de un cofre uso una mochila que tengo al lado de la forja, en definitiva pongo el mineral de hierro a separar en la mochila y sigo las instrucciones que salen de abrir el contenedor y darle a esc. pero se repiten una y otra vez y no empieza, que podria hacer?¿

[f.nandoco]

Nandoco compañero la macro se queda pillada al principio, en vez de un cofre uso una mochila que tengo al lado de la forja, en definitiva pongo el mineral de hierro a separar en la mochila y sigo las instrucciones que salen de abrir el contenedor y darle a esc. pero se repiten una y otra vez y no empieza, que podria hacer?¿

okis tio, ahora me conecto y la miro a ver que la pasa y te cuento en un ratillo

[f.nandoco]

la acabo de probar y va perfectamente, a lo mejor un poco lenta al separar los ores pero por lo demas sin problema.

Lo de que sea una mochila o un cofre, es da igual porque la macro coge la ID de la mochila o cofre y coge los ores de esa mochila, los separarlos, lo funde, y lo guarda en esa misma mochila/cofre. Te cuanto como lo hago yo...

1- abro la mochila del pj, lo dejo abierta, y la muevo a un lado de la pantalla donde no me estorba (la pongo en el lado derecho superior de la pantalla)
2- uso un cofre que esta cerca de la forja (acuerdate de tenerle bloqueado o asegurado para que no te desaparezca) donde tengo todos los ores
3- le doy al play, para iniciar la macro. Lo primero que te pide es que abras el cofre donde estan los ores (este tienes que dejarla abierto tambien, sino no te funciona la macro) y le das a ESC
4- con el puntero, sin pulsar ni abrir ninguna otra mochila o cofre, le pones en el centro de la mochila del pj (yo como la dejo en la parte superior derecha, pongo el puntero del raton en esa parte) y le das a ESC
5- ahora toca ir a tomar un cafe o una cocacola jejejjejjejje

En cuanto a la macro de minar, yo encontre una por el foro pero como casi todas las macros que estan subidas, no funcionan muy bien. Te copio en este mismo enlace, la macro que tengo yo. Es una macro, bajada del foro y reparada.
Hay dos partes de la macro que tienes que configurar antes de iniciar la macro, que es "set %runacasa" y "set %runamina". En la macro te viene todo bien explicado, si tienes alguna duda sobre ella, estare encantado de ayudarte.

saludos y a macrear como loco jejejjejejjej


; ------------------------------------------------------
; Macro de Minar para UA-Sphere (Sphere 0.56b-Nightly)
; Creado por: Alex
; Ultima edición: 08/04/2010 por darksplit
; Modificaciones de: DaviD JoneS, darksplit, f.nandoco (reparada).
; ------------------------------------------------------
;
; Explicación:
; Esta macro ha sido creada para Minar dejando el mineral en casa con la ayuda de Runas.
; Al comienzo y cada vez que vuelva a casa, se comprobará el número de regs del personaje,
; y se cogerán los necesarios para volver a tener 5 de cada para evitar pérdidas en el caso de una
; matanza de un PK en la mina.
; Se meditará antes y después de recalear para subir el maná para acelerar el proceso,
; aún así, no es realmente necesaria la skill de Meditar.
; Minará por toda la mina, de manera aleatoria, pero evitando volver a minar allí dónde ya lo hiciste.
;
;
;
; IMPORTANTE:
; - Debes estar, al dar Play, en el lugar donde te deja la runa que te devuelve a casa.
; - Las runas de las minas deben estar marcadas DENTRO de ellas.
; - No se funde el material, macro de separar/fundir disponible en el foro
; - Sólo se podrá utilizar la macro en las minas preestablecidas, mostradas a continuación.
; - No es necesario tener regs de recall encima al iniciar la Macro, lo comprueba y coge automáticamente.
; - Regs y Mineral deberan estar en el MISMO CONTENEDOR.
; - Esta macro mina únicamente en una mina de tu elección.
; - Skill de Magia a 30 para poder recalear.
;
;
; Configuración:
; - Hueco donde tengas la runa que te llevará al cofre para guardar los minerales (1-16)
;--------------------
set %runacasa 1
;--------------------
; - Hueco donde tengas la runa que te llevará DENTRO de la mina (1-16)
;--------------------
set %runamina 2
;--------------------
; - Elige una mina de la lista a continuación y escribe su número en la variante siguiente:
; -------------------
set %lugar 2 ; Mina en la que actuará la macro
; -------------------
; Las Minas actuales son:
; 0- Ninguna (Mina solo igual, pero si se sale de dentro de la mina no se volverá a meter, deberás moverlo tu)
; 1- Shame (Norte de la entrada Shame (Trabajos Forzados))
; 2- Covetous 1 (Primera Mina a la derecha de la Dungeon Covetous)
; 3- Covetous 2 (Segunda Mina a la derecha de la Dungeon Covetous)
; 4- Covetous 3 (De las dos minas juntas en Covetous Norte, la de arriba)
; 5- Covetous 4 (De las dos minas juntas en Covetous Norte, la de abajo, meterse bien adentro antes de iniciar la macro)
; 6- Minoc Ciudad 1 (La mina que hay al Este de Minoc, pasando el puente)
; 7- Minoc Ciudad 2 (La mina al lado de la que hay pasando el puente de Minoc)
; 8- Minoc Mina 1 (De las Minas del Norte de Minoc, la primera de la izquierda abajo)
; 9- Minoc Mina 2 (De las Minas del Norte de Minoc, la de la izquierda donde hay dos (Haven))
; 10- Minoc Mina 3 (De las Minas del Norte de Minoc, la de la derecha donde hay dos (Haven))
; 11- Destard 1 (Un poco a la izquierda de La Dungeon Destard)
; 12- Destard 2 (Desde la entrada de Destard Dungeon bajando bordeando, la primera mina que encuentras)
; 13- Destard 3 (Desde la entrada de Destard Dungeon bajando bordeando, la segunda mina que encuentras)
; 14- Destard 4 (Desde la entrada de Destard Dungeon bajando bordeando, la terera mina que encuentras, en la de la parte derecha de la montaña)
; 15- Wrong 1 (Junto a la entrada de la Dungeon de Wrong)
; 16- Wrong 2 (Bordendo la montaña desde la entrada de Wrong hacia la izquierda, la primera que encuentras)
; 17- Wrong 3 (Bordendo la montaña desde la entrada de Wrong hacia la izquierda, la segunda que encuentras)
; 18- Hythloth 1 (Bordeando la montaña, hacia arriba desde Hythloth, la primera que encuentras)
; 19- Hythloth 2 (Bordeando la montaña, hacia abajo derecha de Hythloth, la primera Mina que encuentras)
; 20- Hythloth 3 (Bordeando la montaña, hacia abajo derecha de Hythloth, la segunda Mina que encuentras)
; 22- Avatar Norte 1 (De la montaña del Norte de Avatar, la primera que encuentas)
; 23- Avatar Norte 2 (De la montaña del Norte de Avatar, desde la primera, a la derecha bordeando, la primera que encuentras)
; 24- Desierto (En el cruce de caminos)
; 25- Shame Sur
; ==================================


chooseskill mini real
set %skillini #skill
set %locs LOCATIONS_PISADAS
set %borrado 0
set #SYSMSGCOL 0000
event sysmessage Iniciando Macro...
event sysmessage
gosub lugares

configurar:
if %confp = 1 || %confp = N/A
{
set #SYSMSGCOL 1264
setuotitle Abre el contenedor donde dejar los minerales y donde estaran los Regs
event sysmessage ================
event sysmessage Abre el contenedor donde dejar
event sysmessage los Minerales
event sysmessage y donde estaran los Regs de Recall.
event sysmessage Presiona la tecla ESC.
event sysmessage ================
set %conf 1
set %confp 2
goto TESC
}
if %confp = 2
{
set #SYSMSGCOL 1264
setuotitle Abre el Libro de Runas donde tengas las runas a tu Casa y a la Mina y presiona ESC
event sysmessage ================
event sysmessage Abre el Libro de Runas donde tengas las runas de Casa y Mina.
event sysmessage Presiona la tecla ESC.
event sysmessage ================
set #SYSMSGCOL 0000
set %conf 2
goto TESC
}

TESC:
onHotKey ESC
{
if %conf = 1
{
set %idcaja #LOBJECTID
set %dondecasax #CHARPOSX
set %dondecasay #CHARPOSY
set %dondeminax 0
gosub regs
set #SYSMSGCOL 1000
event Sysmessage Desequipando manos...
event macro 24 2
wait 15
goto configurar
}
if %conf = 2
{
set %runebook #LOBJECTID
goto recallmina
}
}
goto TESC

comienzo:
findItem NPF
if #FINDSTACK = 0
{
findItem QPF
}
set #LOBJECTID #FINDID
set %cmsg #JINDEX
wait 5 ; añadido
event macro 17
wait 10
set %fmsg #JINDEX
for %i %cmsg %fmsg
{
scanJournal %i
if Donde_quieres_utilizar in #JOURNAL
{
set %seguridad 0
goto acabapicar
}
}
goto comienzo

acabapicar:
set %cmsg #JINDEX
set #LTARGETX #CHARPOSX + 1
set #LTARGETY #CHARPOSY - 1
wait 5 ; añadido
event macro 22
wait 10
set %fmsg #JINDEX
for %i %cmsg %fmsg
{
scanJournal %i
if Pones_el in #journal || No_encuentras in #JOURNAL ; Consigue minar, y lo vuelve a hacer.
{
set %skillinc #SKILL - %skillini
setuotitle Skill de Mining | Inicial: %skillini | Actual: #SKILL | Incremento: %skillinc | Peso: #WEIGHT
gosub compruebapeso
goto comienzo
}
if Aqui_no_hay_nada_por in #JOURNAL || Prueba_a in #JOURNAL || You_cannot_mine_so in #JOURNAL || No_puedes_ver_bien in #JOURNAL ; No se puede minar, cambio de lugar.
{
gosub compruebapeso
goto moverse
}
}
gosub seguridad
goto acabapicar

moverse:
if %lugar > 0
{
if #CHARPOSX , _ , #CHARPOSY notIn %locs
{
set %borrado %borrado + 1
if %borrado > 100
{
set %locs LOCATIONS_PISADAS
set %borrado 0
}
set %locs %locs , _ , #CHARPOSX , _ , #CHARPOSY
}
if %lugar = 5
{
if %lugaro > #CHARPOSX
{
for %i 1 6
{
event macro 5 3
wait 10
}
}

}
if %lugarp = X
{
if %lugaro < #CHARPOSX
{
for %i 1 6
{
event macro 5 7
wait 10
}
}
}
if %lugarp = Y
{
if %lugaro < #CHARPOSY
{
for %i 1 6
{
event macro 5 1
wait 10
}
}
}
}
set %mover #RANDOM % 7
event macro 5 %mover
wait 20
event macro 5 %mover
wait 20
if #CHARPOSX , _ , #CHARPOSY in %locs
{
goto moverse
}
goto comienzo

recallcasa:
set %posruna %runacasa
gosub librecall
set #LOBJECTID %runebook
event macro 17
wait 20
click %runex %runey f
event macro 13 46
wait 10s
event macro 13 46
msg .resend $
wait 10
if #CHARPOSX = %dondecasax && #CHARPOSY = %dondecasay
{
gosub abrir_cofre
gosub regs
goto dejarminerales
}
else
{
event macro 13 46
goto recallcasa
}

recallmina:
IF #WEIGHT >= 70
{
goto dejarminerales
}
set %posruna %runamina
gosub librecall
set #LOBJECTID %runebook
event macro 17
wait 20
click %runex %runey f
event macro 13 46
wait 10s
event macro 13 46
msg .resend $
wait 10
if %dondeminax = 0
{
if #CHARPOSX <> %dondecasax && #CHARPOSY <> %dondecasay
{
set %dondeminax #CHARPOSX
set %dondeminay #CHARPOSY
}
}
if #CHARPOSX = %dondeminax && #CHARPOSY = %dondeminay
{
event macro 13 46
goto comienzo
}
else
{
goto recallmina
}

dejarminerales:
set %v1 %v1 + 1
if %v1 > 12
{
set %v1 0
goto recallmina
}
wait 10
finditem TVJ c_ , #BACKPACKID
if #FINDSTACK = 0
{
findItem GWJ C_ , #BACKPACKID
if #FINDSTACK = 0
{
findItem EWJ C_ , #BACKPACKID
if #FINDSTACK = 0
{
findItem DWJ C_ , #BACKPACKID
if #FINDSTACK = 0
{
goto recallmina
}
}
}
}
exevent drag #FINDID #FINDSTACK
wait 20
exevent dropc %idcaja
wait 20
goto dejarminerales

sub abrir_cofre
set #LOBJECTID %idcaja
event macro 17 0
wait 30
return

sub regs
set #SYSMSGCOL 1100
event sysmessage ================
event sysmessage Comprobando y cogiendo Regs...
gosub mandrake
gosub black
gosub blood
event sysmessage ================
return

sub mandrake
finditem MZF C_ , #BACKPACKID
event sysmessage Mandrake antes: #FINDSTACK
if #FINDSTACK <= 4
{
set %regcnt #FINDSTACK
set %reg MZF
gosub coger
}
finditem MZF C_ , #BACKPACKID
event sysmessage Mandrake: #FINDSTACK
return

sub black
finditem KUF C_ , #BACKPACKID
event sysmessage Black Pearl antes: #FINDSTACK
if #FINDSTACK <= 4
{
set %regcnt #FINDSTACK
set %reg KUF
gosub coger
}
finditem KUF C_ , #BACKPACKID
event sysmessage Black Pearl: #FINDSTACK
return

sub blood
finditem JUF C_ , #BACKPACKID
event sysmessage Blood Moss antes: #FINDSTACK
if #FINDSTACK <= 4
{
set %regcnt #FINDSTACK
set %reg JUF
gosub coger
}
finditem JUF C_ , #BACKPACKID
event sysmessage Blood Moss: #FINDSTACK
return

sub coger
set %debocoger 5 - %regcnt
finditem %reg C_ , %idcaja
exevent drag #FINDID %debocoger
wait 10
exevent dropc #BACKPACKID
wait 10
return

sub librecall
{
if %posruna < 9
{
set %runex 130
if %posruna = 1
{
set %y 0
}
else
{
set %runea %posruna - 1
set %y 15 * %runea
}
set %runey 70 + %y
}
if %posruna > 8
{
set %runex 290
if %posruna = 9
{
set %y 0
}
else
{
set %runea %posruna - 9
set %y 15 * %runea
}
set %runey 70 + %y
}
return
}

sub seguridad
{
set %seguridad %seguridad + 1
if %seguridad > 15
{
set %seguridad 0
goto comienzo
}
return
}

sub lugares
{
if %lugar = 1
{
set %lugaro 1460
set %lugarp Y
}
if %lugar = 2
{
set %lugaro 2448
set %lugarp X
}
if %lugar = 3
{
set %lugaro 910
set %lugarp Y
}
if %lugar = 4
{
set %lugaro 828
set %lugarp Y
}
if %lugar = 5
{
set %lugaro 2355
set %lugarp X
}
if %lugar = 6
{
set %lugaro 499
set %lugarp Y
}
if %lugar = 7
{
set %lugaro 2602
set %lugarp X
}
if %lugar = 8
{
set %lugaro 2426
set %lugarp X
}
if %lugar = 9
{
set %lugaro 2440
set %lugarp X
}
if %lugar = 10
{
set %lugaro 66
set %lugarp Y
}
if %lugar = 11
{
set %lugaro 266
set %lugarp Y
}
if %lugar = 12
{
set %lugaro 1259
set %lugarp X
}
if %lugar = 13
{
set %lugaro 2729
set %lugarp Y
}
if %lugar = 14
{
set %lugaro 2895
set %lugarp Y
}
if %lugar = 15
{
set %lugaro 1991
set %lugarp X
}
if %lugar = 16
{
set %lugaro 1499
set %lugarp X
}
if %lugar = 17
{
set %lugaro 1941
set %lugarpX
}
if %lugar = 18
{
set %lugaro 1918
set %lugarp X
}
if %lugar = 19
{
set %lugaro 3822
set %lugarp Y
}
if %lugar = 20
{
set %lugaro 4766
set %lugarp X
}
if %lugar = 21
{
set %lugaro 4817
set %lugarp X
}
if %lugar = 22
{
set %lugaro 3302
set %lugarp Y
}
if %lugar = 23
{
set %lugaro 4554
set %lugarp X
}
if %lugar = 24
{
set %lugaro 1812
set %lugarp X
}
if %lugar = 25
{
set %lugaro 1695
set %lugarp Y
}
return
}

sub compruebapeso
{
if #WEIGHT >= #MAXWEIGHT - 25
{
goto recallcasa
}
return
}

[Pikarumon]

Esa macro de minar es la que yo utilizo, pero me daba fallo a la hora de utilizar el libro de runas o al meditar, se quedaba pillao y solo ponia "estas en paz"una y otra vez y nunca viajaba a la mina, lo hacia yo manualmente y al poder estar desatendido me lie a borrar cosas de la macro y ahora solo mina como loco por donde pasa, pero sube muy muy lento y pierdo el mineral k me vendria muy bien para subir herreria luego. Tengo un lio con las macros yo... Gracias por el interes que te estas tomando ^^

P.D.: Me sigue dando fallo, pongo la macro, tengo la mochila un banco y la forja con el yunke, me pongo en posicion k alcance las dos cosas, abro la bolsa con el mineral como me dice y le doy a esc, pongo el cursor en la mochila del jugador abierta y le doy a esc, y acto seguido dice separando orbes no separa nada y vuelta a empezar a marcar la mochila y demas, esto una y otra vez, igual me salto algn paso o en algo debo de fallar no se

[Olwe]

Si la macro de minar te da fallo es por que ministra el libro de runas y tienes que configurarla

[Pikarumon]

no entiendo eso de ministra, y la configuro puse las runas en el numero correspondiente que decia y seleccione la mina que queria de la lista, y se quedaba pillado en la parte de meditar, en los 15 segundos creo que da de margen entre que medita y no lograba transportarme a la mina y empezaba a minar, pero luego al volver a casa tenia el mismo fallo en la mina, tenia que viajar yo manualmente, un lio

[Olwe]

Quise decir que movistes el libro de runas ¡¡¡

[Nilaween]

Si quereis una de fundir de uno en uno en cuanto pueda os la hago, que con easyuo es facil y muy rápido.

[Pikarumon]

Nidea tio las macros no me quieren O.o, nilaween gracias si pudieras pasarme una macro la cual sea capaz de poner en marcha me ayudarias un monton